(無題)

 投稿者：SECOND  投稿日：2011年12月26日(月)18時39分37秒
  !某サイト「考える葦」に掲示されている問題を、グラフ化したものです。
!実際的な確認ができます。数学的 証明の糸口に・・
!-------------------------------------------------------

!ベクトルの問題なんですが・・・ 返信  引用
!名前：・・・    日付：2011/12/24(土) 11:10
!四角形 ABCD において、辺 AB,BC,CD,DA の中点を、それぞれ E,F,G,H とし、
!対角線 AC,BD の中点をそれぞれ I,J とする。
!このとき、線分 EG,FH,IJ は、１点で交わることを証明せよ。
!-------------------------------------------------------

OPTION ARITHMETIC COMPLEX
SET WINDOW -1.1, 1.1, -1.1, 1.1
SET POINT STYLE 7
!
LET a=COMPLEX(-.5, .5)
LET b=COMPLEX(-.7,-.7)
LET c=COMPLEX( .8,-.8)
LET d=COMPLEX( .4, .7)
DO
   SET DRAW mode hidden
   CLEAR
   CALL gide(-1,1)
   !
   SET LINE width 1
   SET LINE COLOR "black"
   PLOT LINES: a;b;c;d;a
   PLOT TEXT,AT a:"A"
   PLOT TEXT,AT b:"B"
   PLOT TEXT,AT c:"C"
   PLOT TEXT,AT d:"D"
   !
   SET LINE COLOR "green"
   LET e=(a+b)/2
   LET f=(b+c)/2
   LET g=(c+d)/2
   LET h=(d+a)/2
   PLOT LINES: e;f;g;h;e
   PLOT POINTS: e;f;g;h
   PLOT TEXT,AT e:"E"
   PLOT TEXT,AT f:"F"
   PLOT TEXT,AT g:"G"
   PLOT TEXT,AT h:"H"
   !
   PLOT LINES: a;c
   PLOT LINES: b;d
   !
   SET LINE width 2
   SET LINE COLOR "red"
   PLOT LINES: e; g
   PLOT LINES: f; h
   !
   SET LINE COLOR "blue"
   PLOT LINES: (a+c)/2;(b+d)/2
   PLOT POINTS: (a+c)/2;(b+d)/2
   PLOT TEXT,AT (a+c)/2:"I"
   PLOT TEXT,AT (b+d)/2:"J"
   !
   SET DRAW mode explicit
   mouse poll x,y,mlb,mrb
   DO WHILE mlb=0 AND mrb=0
      WAIT DELAY 0          !省電力（待機中のクロックアップ防止。)
      mouse poll x,y,mlb,mrb
      LET z=COMPLEX(x,y)
      LET i$=""
      LET i=MIN( MIN( MIN(ABS(z-a),ABS(z-b)),ABS(z-c)),ABS(z-d))
      IF i<=1/6 THEN
         IF i=ABS(z-a) THEN LET i$="a"
         IF i=ABS(z-b) THEN LET i$="b"
         IF i=ABS(z-c) THEN LET i$="c"
         IF i=ABS(z-d) THEN LET i$="d"
      END IF
   LOOP
   LET z=COMPLEX(x,y)
   IF i$="a" THEN
      LET a=z
   ELSEIF i$="b" THEN
      LET b=z
   ELSEIF i$="c" THEN
      LET c=z
   ELSEIF i$="d" THEN
      LET d=z
   END IF
LOOP UNTIL 0< mrb

!------------
SUB gide(x,y)
   PLOT TEXT,AT x,y:"左ボタン押下で、A, B, C, D ４点をドラッグ、自由に変形。"
   PLOT TEXT,AT x,y-.07:"右ボタン終了。"
END SUB
!------------

END
 

戻る