スターリング数

 投稿者：山中和義  投稿日：2012年 9月 3日(月)10時32分26秒
  問題
1からnまでの自然数の中から異なる4つを選んで積をつくる。
その総和をS[n]とするとき、S[n]を求めよ。

例
N=4の場合、1*2*3*4　計C(4,4)=1通り なので、S[4]=24
N=5の場合、1*2*3*4、1*2*3*5、1*2*4*5、1*3*4*5、2*3*4*5　計C(5,4)=5通り なので、S[5]=274




!!OPTION ARITHMETIC RATIONAL !有理数モード

LET N=13

LET S=0
FOR A=1 TO N-3 !組(A,B,C,D)
   FOR B=A+1 TO N-2
      FOR C=B+1 TO N-1
         FOR D=C+1 TO N
            LET S=S+A*B*C*D
         NEXT D
      NEXT C
   NEXT B
NEXT A
PRINT S !結果を表示する

PRINT StirlingS1(n+1,n+1-4) !検算

END


EXTERNAL FUNCTION StirlingS1(n,k) !第1種スターリング数　※n＞0
IF k<1 OR k>n THEN
   LET StirlingS1=0
ELSEIF k=n THEN
   LET StirlingS1=1
ELSE
   LET StirlingS1=(n-1)*StirlingS1(n-1,k) + StirlingS1(n-1,k-1)
END IF
END FUNCTION


EXTERNAL FUNCTION StirlingS2(n,k) !第2種スターリング数　※n＞0
IF k<1 OR k>n THEN
   LET StirlingS2=0
ELSEIF k=1 OR k=n THEN
   LET StirlingS2=1
ELSE
   LET StirlingS2=k*StirlingS2(n-1,k) + StirlingS2(n-1,k-1)
END IF
END FUNCTION


第1種スターリング数

n＼k
0  1
0  1  1
0  2  3  1
0  6  11  6  1
0  24  50  35  10  1
0  120  274  225  85  15  1
0  720  1764  1624  735  175  21  1
0  5040  13068  13132  6769  1960  322  28  1
0  40320  109584  118124  67284  22449  4536  546  36  1
0  362880  1026576  1172700  723680  269325  63273  9450  870  45  1
0  3628800  10628640  12753576  8409500  3416930  902055  157773  18150  1320  55  1
0  39916800  120543840  150917976  105258076  45995730  13339535  2637558  357423  32670  1925  66  1
0  479001600  1486442880  1931559552  1414014888  657206836  206070150  44990231  6926634  749463  55770  2717  78  1
 		 

Re: スターリング数

 投稿者：山中和義  投稿日：2012年 9月 4日(火)10時53分42秒
  > No.1965[元記事へ]

> 階乗関数による表現

●第1種スターリング数 S1(n,m)


!第1種スターリング数 S1(n,m)

!階乗関数 F[k](x)=x(x+1)(x+2) … (x+k-1)、F[0]=1 とする。
!展開式
!　F[n](x)=Σ[m=0,n]{a[m] x^m}
!と表されるときの係数a[m]である。

OPTION ARITHMETIC RATIONAL !有理数モード

LET K=10 !次数

DIM A(0 TO K) !係数　a[k]x^k+a[k-1]x^(k-1)+a[k-2]x^(k-2)+ … +a[1]x+a[0]
MAT A=ZER
LET A(0)=1 !定数項 1

FOR J=0 TO K-1 !k回
   LET A(J+1)=1 !x^(J+1)　※上位から
   FOR i=J TO 1 STEP -1 !x^Jからxまで
      LET A(i)=A(i-1)+A(i)*J !順次(X+J)をかける
   NEXT i
   LET A(0)=A(0)*J !x^0

   MAT PRINT A; !結果を表示する
NEXT J

END


実行結果

0  1  0  0  0  0  0  0  0  0  0

0  1  1  0  0  0  0  0  0  0  0

0  2  3  1  0  0  0  0  0  0  0

0  6  11  6  1  0  0  0  0  0  0

0  24  50  35  10  1  0  0  0  0  0

0  120  274  225  85  15  1  0  0  0  0

0  720  1764  1624  735  175  21  1  0  0  0

0  5040  13068  13132  6769  1960  322  28  1  0  0

0  40320  109584  118124  67284  22449  4536  546  36  1  0

0  362880  1026576  1172700  723680  269325  63273  9450  870  45  1



●第2スターリング数 S2(n,m)


!第2スターリング数 S2(n,m)

!階乗関数 F[k](x)=x(x-1)(x-2) … (x-k+1)、F[0]=1 とする。
!x^kを階乗関数で
!　x^k=Σ[m=0,k]{a[m] F[m](x)}、ただし、a[m]は係数
!となるように表すときの係数a[m]である。
!
!組立除法を繰り返し使って求めることができる。（テイラー展開と同様）

OPTION ARITHMETIC RATIONAL !有理数モード

LET K=10 !次数

DIM A(0 TO K) !係数　a[0]F[k](x)+a[1]F[k-1](x)+a[3]F[k-2](x)+ … +a[k]F[0](x)
MAT A=ZER !x^k=1*x^k+0*x^(k-1)+ … +0*x^1+0*x^0
LET A(0)=1

FOR M=K TO 0 STEP -1
   LET X=K-M !0,1,2,3,…

   FOR i=1 TO M !組立除法
      LET A(i)=A(i-1)*X+A(i)
   NEXT i
   !!!MAT PRINT A; !debug

   FOR i=0 TO M !結果を表示する　※右斜めに見る
      PRINT USING "######": A(i);
   NEXT i
   PRINT
NEXT M

END


実行結果　　※右斜めに見る

     1     0     0     0     0     0     0     0     0     0     0
     1     1     1     1     1     1     1     1     1     1
     1     3     7    15    31    63   127   255   511
     1     6    25    90   301   966  3025  9330
     1    10    65   350  1701  7770 34105
     1    15   140  1050  6951 42525
     1    21   266  2646 22827
     1    28   462  5880
     1    36   750
     1    45
     1

 		 

Re: スターリング数

 投稿者：山中和義  投稿日：2012年 9月 5日(水)10時15分49秒
  > No.1967[元記事へ]

> ●第1種スターリング数 S1(n,m)

問題
1からnまでの自然数を左から右へ1列に並べて数列を作る。
左端から始まる増加部分列の長さを考えるとき、その長さでその並びを分類せよ。
ただし、
増加部分列とは、次の条件を満たす数を集めた部分列のことをいう。
条件
・自分よりも左にあるどの数よりも大きい数

例 n=3の場合、
　並べ方は、3!=6通り
  1,2,3 なら、1,2,3 で長さ3
  1,3,2 なら、1,3 で長さ2
  2,1,3 なら、2,3 で長さ2
  2,3,1 なら、2,3 で長さ2
  3,1,2 なら、3 で長さ1
  3,2,1 なら、3 で長さ1
　よって、長さ3が1個、長さ2が3個、長さ1が2個となる。

例 n=4の場合、
　1,4,2,3 なら、1,4 で長さ2


答え
長さnは、並び 1,2,3,…,n の1通り
長さ1は、左端がnの並びなので、残りの並びは(n-1)!通り
などは自明である。

自然数nで長さkを、S(n,m)とする。
(n-1)個の数の並びに、n個目の数を加えることを考える。
数nのとき、
　数nで長さが＋１されるので、並び{1,2,…,n-1}で長さ(m-1)が条件である。
　これは、S(n-1,m-1)通り
数n以外のとき、
　この数を除いた(n-1)個の数の並びで長さmが条件である。
　これは、(n-1)*S(n-1,m)通り
よって、漸化式
　S(n,m)=S(n-1,m-1)+(n-1)*S(n-1,m)
を得る。


LET N=4

DIM A(N) !並び
DIM C(N) !個数
MAT C=ZER

CALL PERM(1,N,A, C)

MAT PRINT C; !結果を表示する

END


EXTERNAL SUB PERM(P,N,A(), C()) !順列を生成する
FOR i=1 TO N
   IF A(i)=0 THEN !未使用なら
      LET A(i)=P !使用中

      IF P=N THEN !すべて揃ったら
         MAT PRINT A; !debug

         CALL CalcLIS(N,A, CC) !個数を算出する
         LET C(CC)=C(CC)+1 !更新する
         PRINT "長さ=";CC !debug
      ELSE
         CALL PERM(P+1,N,A, C) !次へ
      END IF

      LET A(i)=0 !元に戻す
   END IF
NEXT i
END SUB


EXTERNAL SUB CalcLIS(N,A(), CC) !左端を含む増加部分列の長さを算出する
LET CC=1 !左端から順に見ていく
LET T=A(1)
FOR J=2 TO N
   IF A(J)>T THEN LET CC=CC+1 !増加なら
   LET T=MAX(A(J),T) !以前のもので最大のもの
NEXT J
END SUB


実行結果

1  2  3  4

長さ= 4
1  2  4  3

長さ= 3
1  3  2  4

長さ= 3
1  4  2  3

長さ= 2
1  3  4  2

長さ= 3
1  4  3  2

長さ= 2
2  1  3  4

長さ= 3
2  1  4  3

長さ= 2
3  1  2  4

長さ= 2
4  1  2  3

長さ= 1
3  1  4  2

長さ= 2
4  1  3  2

長さ= 1
2  3  1  4

長さ= 3
2  4  1  3

長さ= 2
3  2  1  4

長さ= 2
4  2  1  3

長さ= 1
3  4  1  2

長さ= 2
4  3  1  2

長さ= 1
2  3  4  1

長さ= 3
2  4  3  1

長さ= 2
3  2  4  1

長さ= 2
4  2  3  1

長さ= 1
3  4  2  1

長さ= 2
4  3  2  1

長さ= 1
6  11  6  1

 		 

Re: スターリング数

 投稿者：山中和義  投稿日：2012年 9月 6日(木)10時27分39秒
  > No.1967[元記事へ]

> 他の多項式による表現

その１


!第1種スターリング数 S1(n,m)

!n≧2として、
!Σ[m=1,n-1]{S1(n-1,m)(X+1)^m}=Σ[m=1,n]{S1(n,m)X^m}
!例
!1*(x+1)=1+x
!1*(x+1)+1*(x+1)^2=(x+1) + (x^2+2x+1)=2+3x+x^2
!2*(x+1)+3*(x+1)^2+1*(x+1)^3=2(x+1) + 3(x^2+2x+1) + (x^3+3x^2+3x+1)=6+11x+6x^2+x^3
!6*(x+1)+11*(x+1)^2+6*(x+1)^3+1*(x+1)^4=24+50x+35x^2+10x^3+x^4
!　　：
!　　：

OPTION ARITHMETIC RATIONAL !有理数モード

LET K=10 !次数

DIM A(0 TO K) !係数　a[k]x^k+a[k-1]x^(k-1)+a[k-2]x^(k-2)+ … +a[1]x+a[0]
MAT A=ZER !S1(1,1)
LET A(1)=1 !x

MAT PRINT A; !結果を表示する

DIM B(0 TO K) !係数　b[k]x^k+b[k-1]x^(k-1)+b[k-2]x^(k-2)+ … +b[1]x+b[0]
FOR N=2 TO K
   MAT B=A !S1(n-1,m)
   MAT A=ZER

   FOR M=1 TO N-1 !Σ[m=1,n-1]
      FOR J=0 TO M !二項展開 (x+1)^m
         LET A(J+1)=A(J+1)+B(M)*COMB(M,M-J)
      NEXT J
   NEXT M

   MAT PRINT A; !結果を表示する
NEXT N

END



その２


!第1種スターリング数 S1(n,m)

!多項式 F[k](x)=(1+x)(1+2x) … (1+kx) とする。
!展開式
!　F[n](x)=Σ[m=0,n-1]{a[m] x^m}
!と表されるときの係数a[m]である。

!筆算
!　1 　　　　← S1(1,m)
!　  1 　　　×1
! -----
!  1 1 　　　← S1(2,m)
!　  2 2 　　×2
! -------
!  1 3 2 　　← S1(3,m)
!　  3 9 6 　×3
! ----------
!  1 6 11 6　← S1(4,m)
!　　：
!　　：

OPTION ARITHMETIC RATIONAL !有理数モード

LET K=10 !次数

DIM A(0 TO K) !係数　a[k]x^k+a[k-1]x^(k-1)+a[k-2]x^(k-2)+ … +a[1]x+a[0]
MAT A=ZER
LET A(0)=1 !定数項 1

MAT PRINT A; !結果を表示する

FOR J=1 TO K-1
   FOR i=J+1 TO 1 STEP -1 !x^(J+1)からxまで　※上位から
      LET A(i)=A(i)+A(i-1)*J !順次(1+J*X)をかける
   NEXT i

   MAT PRINT A; !結果を表示する
NEXT J

END

 		 

Re: スターリング数

 投稿者：山中和義  投稿日：2012年 9月 9日(日)20時15分36秒
  > No.1965[元記事へ]

問題
相異なるn個のボールと区別のつかないm個の箱がある。
各箱にボールを1個以上配る配り方は何通りあるか。

答え
第2種スターリング数 S2(n,m)


LET N=7 !1≦N
LET M=3 !1≦M≦N

DIM A(M) !分け方（要素数）
PUBLIC NUMERIC C !解 S2(n,m)
LET C=0

CALL try(1,N,M,A,0)

PRINT C

END

EXTERNAL SUB try(P,N,M,A(),S) !各箱に配るボールの個数に着目して、数え上げる。
!例　N=7,M=3の場合
!たとえば、1+1+5、1+5+1、5+1+1の3種類あるが、1+1+5 のみとする。
IF P>1 THEN LET T=A(P-1) ELSE LET T=1 !※昇順
FOR i=T TO N !自然数nをm個の自然数の和で表す
   LET W=S+i
   IF W<=N THEN
      LET A(P)=i !p番目は数字iとする

      IF P<M THEN
         CALL try(P+1,N,M,A,W) !次へ
      ELSE
         IF W=N THEN !すべて並んだら
            MAT PRINT A; !debug

            !並び c,…,c, … ,b,…,b,a,…,a として、
            !     L[c]個      L[b]個 L[a]個
            !n=0
            !　C(n+a,a)/1 * C(n+2a,a)/2 * C(n+3a,a)/3 * … * C(n+L[a]*a,a)/L[a]
            !n=L[a]*a
            !　C(n+b,b)/1 * C(n+2b,b)/2 * C(n+3b,b)/3 * … * C(n+L[b]*b,b)/L[b]
            !n=L[a]*a+L[b]*b
            !　　　：
            !n=L[a]*a+L[b]*b+ …
            !　C(n+c,c)/1 * C(n+2c,c)/2 * C(n+3c,c)/3 * … * C(n+L[c]*c,c)/L[c]
            !のように、式を逆から順に遡る。
            !例　N=7,M=3の場合
            !　1,1,5 なら、並べ方は、7!/(1!1!5!) = C(7,1)C(6,1)C(5,5) 通りであるが、
            !　1,1の並びは、箱を区別のつくようにして並べたものなので、
            !　2!で割って重複を削除する。
            !　よって、7!/(1!1!5!) / 2! = C(7,1)C(6,1)/2! C(5,5)/1!
            !　以下、同様
            !　1,2,4 なら、7!/(1!2!4!) / 1! = C(7,1)/1! C(6,2)/1! C(4,4)/1!
            !　1,3,3 なら、7!/(1!3!3!) / 2! = C(7,1)/1! C(6,3)C(3,3)/2!
            !　2,2,3 なら、7!/(2!2!3!) / 2! = C(7,2)C(5,2)/2! C(3,3)/1!
            LET X=1 !場合の数
            LET D=0 !個数の総数
            LET AA=-1 !1つ前
            LET L=1 !出現回数 L[k]
            FOR K=M TO 1 STEP -1
               LET E=A(K)
               IF E=AA THEN !出現回数を更新する
                  LET L=L+1
               ELSE
                  LET L=1
                  LET AA=E
               END IF
               LET D=D+E
               LET X=X*COMB(D,E)/L !重複を削除する
            NEXT K
            PRINT X !debug

            LET C=C+X !累計
         END IF
      END IF

   END IF
NEXT i
END SUB

 		 

Re: スターリング数

 投稿者：山中和義  投稿日：2012年 9月11日(火)11時03分58秒
  > No.1970[元記事へ]

> 問題
> 相異なるn個のボールと区別のつかないm個の箱がある。
> 各箱にボールを1個以上配る配り方は何通りあるか。
>
> 答え
> 第2種スターリング数 S2(n,m)

漸化式をもとに並びを列挙してみました。


!第2種スターリング数 S2(n,k) になる並びの列挙

LET N=7 !1≦N
LET K=3 !1≦K≦N

LET M=StirlingS2(N,K)
PRINT M !debug
DIM A$(M,K) !m個の並び
FOR i=1 TO M
   FOR J=1 TO K
      LET A$(i,J)=""
   NEXT J
NEXT i

LET C=0
CALL try(N,K, C,A$)

FOR i=1 TO C !結果を表示する
   PRINT i;": ";
   FOR J=1 TO K
      PRINT A$(i,j);" ";
   NEXT J
   PRINT
NEXT i

END


!第2種スターリング数の表と漸化式との関連
!   ×1 ×2 ×3  ×4  ×5  ×6  ×7 …
!1: 1
!2: ①  ①
!    ＼│
!3: ① (3)  ①
!    ＼│ ＼│
!4: ① (7)  (6)  1
!    ＼│ ＼│
!5: ① (15) (25) 10   1
!    ＼│ ＼│
!6: 1  (31) (90) 65   15   1
!         ＼│
!7: 1  63   301  350  140  21  1
!　　　　：
!　　　　：
EXTERNAL SUB try(N,K, C,A$(,)) !漸化式をもとに並びを列挙していく
IF K=1 THEN !左端 S2(n,1) のとき、並び{1,2,3,…,n}
   LET C=1
   LET A$(C,1)="1"
   FOR i=2 TO N
      LET A$(C,1)=A$(C,1) & "," & STR$(i)
   NEXT i
   LET A$(C,1)="{" & A$(C,1) & "}"
   PRINT N;K;C !debug

ELSEIF K=N THEN !対角線位置 S2(n,n) のとき、並び{{1},{2},{3},…,{n}}
   LET C=1
   FOR i=1 TO N
      LET A$(C,i)="{" & STR$(i) & "}"
   NEXT i
   PRINT N;K;C !debug

ELSE
!漸化式 S2(n,k) = S2(n-1,k-1) + k*S2(n-1,k) より、

!左側　並び{(1,2,3,…,n-1),{n]}
!ただし、(1,2,3,…,n-1)は、1から(n-1)までの数字による(k-1)個の並びである。
   LET T=StirlingS2(N-1,K-1) !作業変数
   DIM L$(T,K)
   CALL try(N-1,K-1, L,L$) !S2(n-1,k-1)の並び

   !S2(n,k)の並びを生成する
   FOR i=1 TO L ! !数字nをk番目に追加する
      FOR J=1 TO K-1
         LET A$(i,J)=L$(i,J)
      NEXT J
      LET A$(i,K)="{" & STR$(N) & "}"
   NEXT i


   !右側　並び[{1,n},2,3,…,k]、[1,{2,n},3,…,k]、… 、[1,2,3,…,{k,n}]
   !ただし、[1,2,3,…,k]は、1から(n-1)までの数字によるk個の並びである。
   LET T=StirlingS2(N-1,K) !作業変数
   DIM R$(T,K),D$(K*T,K)
   CALL try(N-1,K, R,R$) !S2(n-1,k)の並び

   FOR i=1 TO R !数字nを1からk番目に追加する
      FOR J=1 TO K
         FOR M=1 TO K !個数はk倍になる
            IF M=J THEN
               LET W$=R$(i,J)(2:LEN(R$(i,J))-1) !両端の{}を削除する
               LET D$(K*(i-1)+M,J)="{" & W$ & "," & STR$(N) & "}"
            ELSE
               LET D$(K*(i-1)+M,J)=R$(i,J)
            END IF
         NEXT M
      NEXT J
   NEXT i

   !S2(n,k)の並びを生成する
   FOR i=1 TO K*R
      FOR J=1 TO K
         LET A$(i+L,J)=D$(i,J)
      NEXT J
   NEXT i

   LET C=L+K*R !個数
   PRINT "(";N;",";K;")=";C !debug

END IF
END SUB


EXTERNAL FUNCTION StirlingS2(n,k) !第2種スターリング数　※n＞0
IF k<1 OR k>n THEN
   LET StirlingS2=0
ELSEIF k=1 OR k=n THEN
   LET StirlingS2=1
ELSE
   LET StirlingS2=StirlingS2(n-1,k-1) + k*StirlingS2(n-1,k)
END IF
END FUNCTION


実行結果

301
5  1  1
4  1  1
3  1  1
2  1  1
2  2  1
( 3 , 2 )= 3
( 4 , 2 )= 7
( 5 , 2 )= 15
( 6 , 2 )= 31
4  1  1
3  1  1
2  1  1
2  2  1
( 3 , 2 )= 3
( 4 , 2 )= 7
( 5 , 2 )= 15
3  1  1
2  1  1
2  2  1
( 3 , 2 )= 3
( 4 , 2 )= 7
2  1  1
2  2  1
( 3 , 2 )= 3
3  3  1
( 4 , 3 )= 6
( 5 , 3 )= 25
( 6 , 3 )= 90
( 7 , 3 )= 301
1 : {1,2,3,4,5} {6} {7}
2 : {1,2,3,4,6} {5} {7}
3 : {1,2,3,4} {5,6} {7}
4 : {1,2,3,5,6} {4} {7}
5 : {1,2,3,5} {4,6} {7}
6 : {1,2,3,6} {4,5} {7}
7 : {1,2,3} {4,5,6} {7}
8 : {1,2,4,5,6} {3} {7}
9 : {1,2,4,5} {3,6} {7}
10 : {1,2,4,6} {3,5} {7}
11 : {1,2,4} {3,5,6} {7}
12 : {1,2,5,6} {3,4} {7}
13 : {1,2,5} {3,4,6} {7}
14 : {1,2,6} {3,4,5} {7}
15 : {1,2} {3,4,5,6} {7}
16 : {1,3,4,5,6} {2} {7}
17 : {1,3,4,5} {2,6} {7}
18 : {1,3,4,6} {2,5} {7}
19 : {1,3,4} {2,5,6} {7}
20 : {1,3,5,6} {2,4} {7}
21 : {1,3,5} {2,4,6} {7}
22 : {1,3,6} {2,4,5} {7}
23 : {1,3} {2,4,5,6} {7}
24 : {1,4,5,6} {2,3} {7}
25 : {1,4,5} {2,3,6} {7}
26 : {1,4,6} {2,3,5} {7}
27 : {1,4} {2,3,5,6} {7}
28 : {1,5,6} {2,3,4} {7}
29 : {1,5} {2,3,4,6} {7}
30 : {1,6} {2,3,4,5} {7}
31 : {1} {2,3,4,5,6} {7}
32 : {1,2,3,4,7} {5} {6}
33 : {1,2,3,4} {5,7} {6}
34 : {1,2,3,4} {5} {6,7}
35 : {1,2,3,5,7} {4} {6}
36 : {1,2,3,5} {4,7} {6}
37 : {1,2,3,5} {4} {6,7}
38 : {1,2,3,7} {4,5} {6}
39 : {1,2,3} {4,5,7} {6}
40 : {1,2,3} {4,5} {6,7}
41 : {1,2,4,5,7} {3} {6}
42 : {1,2,4,5} {3,7} {6}
43 : {1,2,4,5} {3} {6,7}
44 : {1,2,4,7} {3,5} {6}
45 : {1,2,4} {3,5,7} {6}
46 : {1,2,4} {3,5} {6,7}
47 : {1,2,5,7} {3,4} {6}
48 : {1,2,5} {3,4,7} {6}
49 : {1,2,5} {3,4} {6,7}
50 : {1,2,7} {3,4,5} {6}
51 : {1,2} {3,4,5,7} {6}
52 : {1,2} {3,4,5} {6,7}
53 : {1,3,4,5,7} {2} {6}
54 : {1,3,4,5} {2,7} {6}
55 : {1,3,4,5} {2} {6,7}
56 : {1,3,4,7} {2,5} {6}
57 : {1,3,4} {2,5,7} {6}
58 : {1,3,4} {2,5} {6,7}
59 : {1,3,5,7} {2,4} {6}
60 : {1,3,5} {2,4,7} {6}
61 : {1,3,5} {2,4} {6,7}
62 : {1,3,7} {2,4,5} {6}
63 : {1,3} {2,4,5,7} {6}
64 : {1,3} {2,4,5} {6,7}
65 : {1,4,5,7} {2,3} {6}
66 : {1,4,5} {2,3,7} {6}
67 : {1,4,5} {2,3} {6,7}
68 : {1,4,7} {2,3,5} {6}
69 : {1,4} {2,3,5,7} {6}
70 : {1,4} {2,3,5} {6,7}
71 : {1,5,7} {2,3,4} {6}
72 : {1,5} {2,3,4,7} {6}
73 : {1,5} {2,3,4} {6,7}
74 : {1,7} {2,3,4,5} {6}
75 : {1} {2,3,4,5,7} {6}
76 : {1} {2,3,4,5} {6,7}
77 : {1,2,3,6,7} {4} {5}
78 : {1,2,3,6} {4,7} {5}
79 : {1,2,3,6} {4} {5,7}
80 : {1,2,3,7} {4,6} {5}
81 : {1,2,3} {4,6,7} {5}
82 : {1,2,3} {4,6} {5,7}
83 : {1,2,3,7} {4} {5,6}
84 : {1,2,3} {4,7} {5,6}
85 : {1,2,3} {4} {5,6,7}
86 : {1,2,4,6,7} {3} {5}
87 : {1,2,4,6} {3,7} {5}
88 : {1,2,4,6} {3} {5,7}
89 : {1,2,4,7} {3,6} {5}
90 : {1,2,4} {3,6,7} {5}
91 : {1,2,4} {3,6} {5,7}
92 : {1,2,4,7} {3} {5,6}
93 : {1,2,4} {3,7} {5,6}
94 : {1,2,4} {3} {5,6,7}
95 : {1,2,6,7} {3,4} {5}
96 : {1,2,6} {3,4,7} {5}
97 : {1,2,6} {3,4} {5,7}
98 : {1,2,7} {3,4,6} {5}
99 : {1,2} {3,4,6,7} {5}
100 : {1,2} {3,4,6} {5,7}
101 : {1,2,7} {3,4} {5,6}
102 : {1,2} {3,4,7} {5,6}
103 : {1,2} {3,4} {5,6,7}
104 : {1,3,4,6,7} {2} {5}
105 : {1,3,4,6} {2,7} {5}
106 : {1,3,4,6} {2} {5,7}
107 : {1,3,4,7} {2,6} {5}
108 : {1,3,4} {2,6,7} {5}
109 : {1,3,4} {2,6} {5,7}
110 : {1,3,4,7} {2} {5,6}
111 : {1,3,4} {2,7} {5,6}
112 : {1,3,4} {2} {5,6,7}
113 : {1,3,6,7} {2,4} {5}
114 : {1,3,6} {2,4,7} {5}
115 : {1,3,6} {2,4} {5,7}
116 : {1,3,7} {2,4,6} {5}
117 : {1,3} {2,4,6,7} {5}
118 : {1,3} {2,4,6} {5,7}
119 : {1,3,7} {2,4} {5,6}
120 : {1,3} {2,4,7} {5,6}
121 : {1,3} {2,4} {5,6,7}
122 : {1,4,6,7} {2,3} {5}
123 : {1,4,6} {2,3,7} {5}
124 : {1,4,6} {2,3} {5,7}
125 : {1,4,7} {2,3,6} {5}
126 : {1,4} {2,3,6,7} {5}
127 : {1,4} {2,3,6} {5,7}
128 : {1,4,7} {2,3} {5,6}
129 : {1,4} {2,3,7} {5,6}
130 : {1,4} {2,3} {5,6,7}
131 : {1,6,7} {2,3,4} {5}
132 : {1,6} {2,3,4,7} {5}
133 : {1,6} {2,3,4} {5,7}
134 : {1,7} {2,3,4,6} {5}
135 : {1} {2,3,4,6,7} {5}
136 : {1} {2,3,4,6} {5,7}
137 : {1,7} {2,3,4} {5,6}
138 : {1} {2,3,4,7} {5,6}
139 : {1} {2,3,4} {5,6,7}
140 : {1,2,5,6,7} {3} {4}
141 : {1,2,5,6} {3,7} {4}
142 : {1,2,5,6} {3} {4,7}
143 : {1,2,5,7} {3,6} {4}
144 : {1,2,5} {3,6,7} {4}
145 : {1,2,5} {3,6} {4,7}
146 : {1,2,5,7} {3} {4,6}
147 : {1,2,5} {3,7} {4,6}
148 : {1,2,5} {3} {4,6,7}
149 : {1,2,6,7} {3,5} {4}
150 : {1,2,6} {3,5,7} {4}
151 : {1,2,6} {3,5} {4,7}
152 : {1,2,7} {3,5,6} {4}
153 : {1,2} {3,5,6,7} {4}
154 : {1,2} {3,5,6} {4,7}
155 : {1,2,7} {3,5} {4,6}
156 : {1,2} {3,5,7} {4,6}
157 : {1,2} {3,5} {4,6,7}
158 : {1,2,6,7} {3} {4,5}
159 : {1,2,6} {3,7} {4,5}
160 : {1,2,6} {3} {4,5,7}
161 : {1,2,7} {3,6} {4,5}
162 : {1,2} {3,6,7} {4,5}
163 : {1,2} {3,6} {4,5,7}
164 : {1,2,7} {3} {4,5,6}
165 : {1,2} {3,7} {4,5,6}
166 : {1,2} {3} {4,5,6,7}
167 : {1,3,5,6,7} {2} {4}
168 : {1,3,5,6} {2,7} {4}
169 : {1,3,5,6} {2} {4,7}
170 : {1,3,5,7} {2,6} {4}
171 : {1,3,5} {2,6,7} {4}
172 : {1,3,5} {2,6} {4,7}
173 : {1,3,5,7} {2} {4,6}
174 : {1,3,5} {2,7} {4,6}
175 : {1,3,5} {2} {4,6,7}
176 : {1,3,6,7} {2,5} {4}
177 : {1,3,6} {2,5,7} {4}
178 : {1,3,6} {2,5} {4,7}
179 : {1,3,7} {2,5,6} {4}
180 : {1,3} {2,5,6,7} {4}
181 : {1,3} {2,5,6} {4,7}
182 : {1,3,7} {2,5} {4,6}
183 : {1,3} {2,5,7} {4,6}
184 : {1,3} {2,5} {4,6,7}
185 : {1,3,6,7} {2} {4,5}
186 : {1,3,6} {2,7} {4,5}
187 : {1,3,6} {2} {4,5,7}
188 : {1,3,7} {2,6} {4,5}
189 : {1,3} {2,6,7} {4,5}
190 : {1,3} {2,6} {4,5,7}
191 : {1,3,7} {2} {4,5,6}
192 : {1,3} {2,7} {4,5,6}
193 : {1,3} {2} {4,5,6,7}
194 : {1,5,6,7} {2,3} {4}
195 : {1,5,6} {2,3,7} {4}
196 : {1,5,6} {2,3} {4,7}
197 : {1,5,7} {2,3,6} {4}
198 : {1,5} {2,3,6,7} {4}
199 : {1,5} {2,3,6} {4,7}
200 : {1,5,7} {2,3} {4,6}
201 : {1,5} {2,3,7} {4,6}
202 : {1,5} {2,3} {4,6,7}
203 : {1,6,7} {2,3,5} {4}
204 : {1,6} {2,3,5,7} {4}
205 : {1,6} {2,3,5} {4,7}
206 : {1,7} {2,3,5,6} {4}
207 : {1} {2,3,5,6,7} {4}
208 : {1} {2,3,5,6} {4,7}
209 : {1,7} {2,3,5} {4,6}
210 : {1} {2,3,5,7} {4,6}
211 : {1} {2,3,5} {4,6,7}
212 : {1,6,7} {2,3} {4,5}
213 : {1,6} {2,3,7} {4,5}
214 : {1,6} {2,3} {4,5,7}
215 : {1,7} {2,3,6} {4,5}
216 : {1} {2,3,6,7} {4,5}
217 : {1} {2,3,6} {4,5,7}
218 : {1,7} {2,3} {4,5,6}
219 : {1} {2,3,7} {4,5,6}
220 : {1} {2,3} {4,5,6,7}
221 : {1,4,5,6,7} {2} {3}
222 : {1,4,5,6} {2,7} {3}
223 : {1,4,5,6} {2} {3,7}
224 : {1,4,5,7} {2,6} {3}
225 : {1,4,5} {2,6,7} {3}
226 : {1,4,5} {2,6} {3,7}
227 : {1,4,5,7} {2} {3,6}
228 : {1,4,5} {2,7} {3,6}
229 : {1,4,5} {2} {3,6,7}
230 : {1,4,6,7} {2,5} {3}
231 : {1,4,6} {2,5,7} {3}
232 : {1,4,6} {2,5} {3,7}
233 : {1,4,7} {2,5,6} {3}
234 : {1,4} {2,5,6,7} {3}
235 : {1,4} {2,5,6} {3,7}
236 : {1,4,7} {2,5} {3,6}
237 : {1,4} {2,5,7} {3,6}
238 : {1,4} {2,5} {3,6,7}
239 : {1,4,6,7} {2} {3,5}
240 : {1,4,6} {2,7} {3,5}
241 : {1,4,6} {2} {3,5,7}
242 : {1,4,7} {2,6} {3,5}
243 : {1,4} {2,6,7} {3,5}
244 : {1,4} {2,6} {3,5,7}
245 : {1,4,7} {2} {3,5,6}
246 : {1,4} {2,7} {3,5,6}
247 : {1,4} {2} {3,5,6,7}
248 : {1,5,6,7} {2,4} {3}
249 : {1,5,6} {2,4,7} {3}
250 : {1,5,6} {2,4} {3,7}
251 : {1,5,7} {2,4,6} {3}
252 : {1,5} {2,4,6,7} {3}
253 : {1,5} {2,4,6} {3,7}
254 : {1,5,7} {2,4} {3,6}
255 : {1,5} {2,4,7} {3,6}
256 : {1,5} {2,4} {3,6,7}
257 : {1,6,7} {2,4,5} {3}
258 : {1,6} {2,4,5,7} {3}
259 : {1,6} {2,4,5} {3,7}
260 : {1,7} {2,4,5,6} {3}
261 : {1} {2,4,5,6,7} {3}
262 : {1} {2,4,5,6} {3,7}
263 : {1,7} {2,4,5} {3,6}
264 : {1} {2,4,5,7} {3,6}
265 : {1} {2,4,5} {3,6,7}
266 : {1,6,7} {2,4} {3,5}
267 : {1,6} {2,4,7} {3,5}
268 : {1,6} {2,4} {3,5,7}
269 : {1,7} {2,4,6} {3,5}
270 : {1} {2,4,6,7} {3,5}
271 : {1} {2,4,6} {3,5,7}
272 : {1,7} {2,4} {3,5,6}
273 : {1} {2,4,7} {3,5,6}
274 : {1} {2,4} {3,5,6,7}
275 : {1,5,6,7} {2} {3,4}
276 : {1,5,6} {2,7} {3,4}
277 : {1,5,6} {2} {3,4,7}
278 : {1,5,7} {2,6} {3,4}
279 : {1,5} {2,6,7} {3,4}
280 : {1,5} {2,6} {3,4,7}
281 : {1,5,7} {2} {3,4,6}
282 : {1,5} {2,7} {3,4,6}
283 : {1,5} {2} {3,4,6,7}
284 : {1,6,7} {2,5} {3,4}
285 : {1,6} {2,5,7} {3,4}
286 : {1,6} {2,5} {3,4,7}
287 : {1,7} {2,5,6} {3,4}
288 : {1} {2,5,6,7} {3,4}
289 : {1} {2,5,6} {3,4,7}
290 : {1,7} {2,5} {3,4,6}
291 : {1} {2,5,7} {3,4,6}
292 : {1} {2,5} {3,4,6,7}
293 : {1,6,7} {2} {3,4,5}
294 : {1,6} {2,7} {3,4,5}
295 : {1,6} {2} {3,4,5,7}
296 : {1,7} {2,6} {3,4,5}
297 : {1} {2,6,7} {3,4,5}
298 : {1} {2,6} {3,4,5,7}
299 : {1,7} {2} {3,4,5,6}
300 : {1} {2,7} {3,4,5,6}
301 : {1} {2} {3,4,5,6,7}

 		 

戻る