|
|
! 三相誘導電動機 かご形と巻線形のトルク・電流特性図作成プログラム
!--JEC37 Ｌ型等価回路に依る誘導電動機の特性計算
!--電動機電流は励磁電流を含む
LET nmax=5000
DIM slip(nmax),Pm(nmax), Tm(nmax), CR(nmax)
DIM pf(nmax), TL(nmax),Pin(nmax),Pout(nmax),eff(nmax)
SET WINDOW 1,0,-0.4,4
DRAW grid(0.1,1)
!****ここから、計算データの入力****************
! *** 定格データ
LET Pr =22.0 !定格出力[kW]
LET Vr =200 !定格線間電圧[V]
LET Ir =85 !定格電流[A]
LET Hz =50 !定格周波数[Hz]
LET pole=4 !極数
LET Nr=1450 !定格回転数[rpm]
LET ic$="E" !絶縁種別
LET FM$="K1" !型式 W=巻線形、 C=普通かご形、K1=特殊かご形1種、K2=特殊かご形2種
! **** 無負荷試験（Noload_Test）データ
LET I0=28.7 !無負荷電流[A]
LET W0=680 !無負荷入力[W]
! **** 拘束試験データ (100%周波数)
LET Id=85 !拘束電流[A]
LET Vd=50.6 !拘束電圧[V]
LET Wd=3036 !拘束電力[W]
! **** 拘束試験データ (50%周波数)
LET Idd=85 !拘束電流[A]
LET Vdd=29.8 !拘束電圧[V]
LET Wdd=2319 !拘束電力[W]
! **** 一次・二次巻線抵抗（線間） 温度(Cﾟ) ****
LET R1at=0.1007 !周囲温度における一次巻線抵抗[Ω]
!R2at= !周囲温度における二次巻線抵抗[Ω]
LET Ta=20 !測定周囲温度
! **** 負荷トルク特性設定 ****
LET Ltorq_ID=2 !１は定トルク、２は2乗トルク
LET Tpu=1.0 !定格滑りにおける全負荷トルクの割合指定[pu]
!**********ここまで************************************
LET ds=1/nmax
LET sqr3=sqr(3)
LET pai=3.14159
LET Er=Vr/sqr3 !Ｙ換算定格相電圧[V]
LET Ed=Vd/sqr3
LET Edd=Vdd/sqr3
LET TmR=Pr*1000/2/PI/Nr*60 !定格トルク[N.m]
If ic$ = "A" Or ic$ = "B" Or ic$ = "E" Then !基準温度上昇は75度設定
LET Tb = 310 !'=235+75
LET Kr=1
ElseIf ic$ = "F" Then !基準温度上昇は115度設定
LET Tb = 350 !'=235+115
LET Kr=1.13
Else
pause "絶縁種別記号が誤っています。"
STOP
END IF
LET N0 = 120 * Hz / pole !同期速度[rpm]
LET Tr = Pr*1000/(2*pai*Nr/60) !定格トルク[N-m]
LET R1 = R1at / 2 * Tb / (235 + Ta)
LET y0 = I0 / Er
LET g0 = W0 / Vr / Vr
LET b0 = Sqr(y0 * y0 - g0 * g0)
LET Zd = Ed / Id
LET Rd = Wd / 3 / Id / Id
LET Rd1=Rd
LET Xd = Sqr(Zd * Zd - Rd * Rd)
LET Xd1=Xd
IF FM$="K1" Or FM$="K2" Then
LET Zdd = Edd / Idd
LET Rdd = Wdd / 3 / Idd / Idd
LET Rd2=Rdd
LET Xdd = Sqr(Zdd ^ 2 - Rdd ^ 2)
LET Xd2=2*Xdd
LET h = ( Xd2 - Xd1) / (Rd1 - Rd2)
LET m = (4 + h * h) / 3
IF h<1 Then LET km=1.6
IF h>=1 Then LET km=m
LET Rd3=Rd1-km*(Rd1-Rd2)
LET Xd3=Xd1+km*(Xd2-Xd1)
End IF
LET kv = 1
LET kz = 1
!計算滑りsを設定し特性を計算
FOR kk = 1 TO nmax !滑りをds[pu]刻みで1.0[pu]まで計算
LET s =ds * kk
Call enzan2
NEXT kk
Call sakuzu
Sub enzan2 !---滑りｓ時のモータ特性及び負荷トルク計算----
!モータ定数計算方法は電気工学ハンドブック（昭和５３年版）722頁２章2.1.1に依る。
IF FM$ = "C" Or FM$ = "W" Then
LET X = Xd1
LET R = kr * Rd1
ElseIF FM$ = "K1" Or FM$ = "K2" Then
IF s<=0.2 Then
LET R=kr*Rd3
LET X=Xd3
ElseIF s<=0.5 Then
LET R = kr * (Rd2 -(0.5-s)/0.3* (Rd2 - Rd3))
LET X = Xd2 +(0.5-s)/0.3* (Xd3 - Xd2)
Else
LET R = kr * (Rd1 -(1-s)/0.5* (Rd1 - Rd2))
LET X = Xd1 +(1-s)/0.5* (Xd2 - Xd1)
End IF
Else
pause "電動機の形式記号が誤りです。半角でＣ、Ｗ、Ｋ１又はＫ２を入力して下さい。"
STOP
End If
LET g = R / (R * R + X * X)
LET b = X / (R * R + X * X)
LET g12 = g - g0
LET b12 = b - b0
LET R2 = g12 / (g12 * g12 + b12 * b12) - R1
LET R12s = R1 + R2 / s
LET X12 = b12 / (g12 * g12 + b12 * b12)
LET Z12s = Sqr(R12s ^ 2 + X12 ^ 2)
LET I2 = kv * Er / Z12s / kz
LET I2r = I2 * R12s / Z12s
LET I2x = I2 * X12 / Z12s
LET I0r = kv * Er * g0 / kz
LET I0x = kv *Er * b0 / kz
LET I1 = Sqr((I0r + I2r) ^ 2 + (I0x + I2x) ^ 2)
LET P2 = 3 *kz* R2/ s * I2 ^ 2
LET Mtorq = P2/(2*pai*N0/60)
IF Ltorq_ID =1 Then
LET Ltorq = Tr * Tpu
ELSEIF Ltorq_ID =2 THEN
LET Ltorq = Tr * ((1 - s) * N0 / Nr) ^ 2 * Tpu
End IF
!'*** 特性図作画用出力データの一時記憶 ***
LET TL(kk) = Ltorq
LET slip(kk)=s
LET Pm(kk) = (1 - s) * P2 / 1000
LET Tm(kk) = Mtorq
LET TL(kk)=Ltorq
LET CR(kk) = I1
LET pf(kk) = (I0r + I2r) / I1
LET Pin(kk) = 3 * kv * Er * I1 * pf(kk) / 1000
LET Pout(kk) =2 *pai *N0 /60 * (1 - s) * Tm(kk) / 1000
LET eff(kk)= Pout(kk)/Pin(kk)
End Sub
Sub sakuzu !---特性曲線作図
!---電動機トルク曲線---
FOR kk=1 TO nmax
LET s=kk*ds
PLOT LINES:s,Tm(kk)/TmR;
NEXT kk
PLOT LINES
!---電動機電流曲線---
SET LINE COLOR "red"
FOR kk=1 TO nmax
LET s=kk*ds
PLOT LINES:s,CR(kk)/Ir;
NEXT kk
PLOT LINES
!---負荷トルク曲線---
SET LINE COLOR "green"
FOR kk=1 TO nmax
LET s=kk*ds
PLOT LINES:s,TL(kk)/TmR;
NEXT kk
PLOT LINES
!横軸線の描画
SET LINE COLOR "black"
PLOT LINES:1,0;0,0
PLOT TEXT,AT 0.4,3.8:"赤：電動機電流[pu]"
PLOT TEXT,AT 0.4,3.6:"黒：電動機トルク[pu]"
PLOT TEXT,AT 0.4,3.4:"緑：負荷トルク[pu]"
PLOT TEXT,AT 0.55,-0.35:"滑りs[pu] <---"
pause "作図完了です。"
End Sub
End
|
|