十進BASIC 第2掲示板 過去ログ

!７セグメント数字表示のデジタル時計（Clock）

LET w=400 !画面の大きさ
LET h=120
SET bitmap SIZE w+1,h+1 !ドット単位にする
SET WINDOW 0,w,h,0 !クライアント座標（左上が原点）


LET S0=-1
DO
   LET t$=TIME$ !時刻をhh:mm:ss形式で得る

   LET S=VAL(t$(7:8)) !秒
   IF S<>S0 THEN !更新されたら
      LET S0=S

      LET H=VAL(t$(1:2)) !時
      LET M=VAL(t$(4:5)) !分

      CALL clock_display(INT(H/10),MOD(H,10),INT(M/10),MOD(M,10),INT(S/10),MOD(S,10))
   END IF
LOOP



!電子部品（配置と配線）

!         ↓BCD(h10,h1,m10,m1,s10,s1)
!  ┌─ データラッチ
!  │     ↓BCD
!  │   デコーダ
!  │     ↓abcdefg
!  └→ 88:88:88
!         │
!         GND
SUB clock_display(h10,h1,m10,m1,s10,s1) !表示部
   SET DRAW mode hidden !ちらつき防止(開始)
   CLEAR

   DRAW LED(1,GND) WITH SCALE(20)*SHIFT(155,40) !コロン
   DRAW LED(1,GND) WITH SCALE(20)*SHIFT(155,80)

   !ダイナミック点灯表示
   DRAW DRIVER7segment(h10) WITH SCALE(20)*SHIFT(50,60) !時
   DRAW DRIVER7segment(h1) WITH SCALE(20)*SHIFT(110,60)

   DRAW DRIVER7segment(m10) WITH SCALE(20)*SHIFT(200,60) !分
   DRAW DRIVER7segment(m1) WITH SCALE(20)*SHIFT(260,60)

   DRAW DRIVER7segment(s10) WITH SCALE(15)*SHIFT(320,70) !秒
   DRAW DRIVER7segment(s1) WITH SCALE(15)*SHIFT(370,70)

   SET DRAW mode explicit !ちらつき防止(終了)
END SUB

PICTURE DRIVER7segment(BCD) !７セグメント数字表示にする
   CALL DECODE7segment(BCD, Za,Zb,Zc,Zd,Ze,Zf,Zg)
   DRAW LED7segmentKwithoutDP(Za,Zb,Zc,Zd,Ze,Zf,Zg)
END PICTURE


!電子部品（上位）

SUB DECODE7segment(n, Za,Zb,Zc,Zd,Ze,Zf,Zg) !７セグメント数字表示デコーダ
   IF n=0 THEN
      LET ptn$="1111110" !abcdedfgのオン・オフ状態
   ELSEIF n=1 THEN
      LET ptn$="0110000"
   ELSEIF n=2 THEN
      LET ptn$="1101101"
   ELSEIF n=3 THEN
      LET ptn$="1111001"
   ELSEIF n=4 THEN
      LET ptn$="0110011"
   ELSEIF n=5 THEN
      LET ptn$="1011011"
   ELSEIF n=6 THEN
      LET ptn$="1011111"
   ELSEIF n=7 THEN
      LET ptn$="1110000"
   ELSEIF n=8 THEN
      LET ptn$="1111111"
   ELSEIF n=9 THEN
      LET ptn$="1111011"
   ELSE
      PRINT "不正な値です。"; n
   END IF

   LET Za=VAL(ptn$(1:1))
   LET Zb=VAL(ptn$(2:2))
   LET Zc=VAL(ptn$(3:3))
   LET Zd=VAL(ptn$(4:4))
   LET Ze=VAL(ptn$(5:5))
   LET Zf=VAL(ptn$(6:6))
   LET Zg=VAL(ptn$(7:7))
END SUB

!    --a-      配置位置
!  f|    |b
!    --g-
!  e|    |c
!    --d-
PICTURE LED7segmentKwithoutDP(a,b,c,d,e,f,g) !７セグメント数字表示器  ※カソード・コモン
   DRAW bar(a,GND) WITH SHIFT(0,-2) !※左上が原点
   DRAW bar(b,GND) WITH ROTATE(PI/2)*SHIFT(1,-1)
   DRAW bar(c,GND) WITH ROTATE(PI/2)*SHIFT(1,1)
   DRAW bar(d,GND) WITH SHIFT(0,2)
   DRAW bar(e,GND) WITH ROTATE(PI/2)*SHIFT(-1,1)
   DRAW bar(f,GND) WITH ROTATE(PI/2)*SHIFT(-1,-1)
   DRAW bar(g,GND) WITH SHIFT(0,0)
END PICTURE


!電子部品（下位）

PICTURE bar(a,k) !発光ダイオードを表示する
   IF a=1 AND k=0 THEN
      PLOT AREA: -1,-0.3; 1,-0.3; 1,0.3; -1,0.3 !点灯　※塗り潰し
   ELSE
      PLOT LINES: -1,-0.2; 1,-0.2; 1,0.2; -1,0.2; -1,-0.2 !消灯　※枠
   END IF
END PICTURE

PICTURE LED(a,k) !発光ダイオードを表示する
   IF a=1 AND k=0 THEN
      DRAW disk WITH SCALE(0.4) !点灯
   ELSE
      DRAW circle WITH SCALE(0.4) !消灯
   END IF
END PICTURE

END