|
|
ボカシ処理をします。
スライドバーを動かした後、グラフィックウィンドゥ内をマウスでクリックしてください。
OPTION BASE 0
FILE GETNAME F$,"BMP,JPG,GIF,PNGファイル|*.BMP;*.JPG;*.GIF;*.PNG"
CALL PICTURELOAD(F$,XSIZE,YSIZE)
DIM M(XSIZE-1,YSIZE-1),MM(XSIZE-1,YSIZE-1)
ASK PIXEL ARRAY(0,0) M
LOCATE VALUE NOWAIT(1),RANGE 1 TO 9,AT 1:N
DO
CLEAR
SET TEXT HEIGHT YSIZE/10
SET COLOR COLORINDEX(0,0,0)
SET TEXT BACKGROUND "OPAQUE"
SET TEXT JUSTIFY "CENTER" , "TOP"
PLOT TEXT ,AT XSIZE/2,YSIZE/2 :"処理中"
LET N=INT(N)
FOR Y=0 TO YSIZE-1
SET TEXT JUSTIFY "LEFT" , "TOP"
PLOT TEXT ,AT 0,0 :USING$("###.#",Y/(YSIZE-1)*100)&"%"
FOR X=0 TO XSIZE-1
LET RR=0
LET GG=0
LET BB=0
LET K=0
FOR J=-N TO N
FOR I=-N TO N
IF GetKeyState(32)<0 OR GetKeyState(13)<0 OR GetKeyState(27)<0 THEN STOP
IF X+I>=0 AND X+I<=XSIZE-1 AND Y+J>=0 AND Y+J<=YSIZE-1 THEN
LET C=M(X+I,Y+J)
CALL RGB(C,R,G,B)
LET RR=RR+R
LET GG=GG+G
LET BB=BB+B
LET K=K+1
END IF
NEXT I
NEXT J
LET MM(X,Y)=SETRGB(INT(RR/K),INT(GG/K),INT(BB/K))
NEXT X
NEXT Y
MAT PLOT CELLS , IN 0,0; XSIZE-1,YSIZE-1:MM
DO !'ウェイト。マウスでウィンドゥ内をクリックする。
IF GetKeyState(32)<0 OR GetKeyState(13)<0 OR GetKeyState(27)<0 THEN STOP
MOUSE POLL X,Y,LL,RR
LOCATE VALUE NOWAIT(1):N
LOOP WHILE LL=0 AND RR=0
LOOP
END
EXTERNAL FUNCTION SETRGB(R,G,B)
LET R=MIN(255,MAX(R,0))
LET G=MAX(0,MIN(G,255))
LET B=MAX(0,MIN(B,255))
LET SETRGB=B*65536+G*256+R
END FUNCTION
EXTERNAL SUB RGB(X,R,G,B)
LET B=MOD(INT(X/65536),256)
LET G=MOD(INT(X/256),256)
LET R=MOD(X,256)
END SUB
EXTERNAL SUB PICTURELOAD(N$,XSIZE,YSIZE)
CLEAR
SET COLOR MODE "NATIVE"
SET POINT STYLE 1
IF N$="" THEN STOP
GLOAD N$
LET XSIZE=PIXELX(1)+1
LET YSIZE=PIXELY(1)+1
SET BITMAP SIZE XSIZE,YSIZE
SET WINDOW 0,XSIZE-1,YSIZE-1,0
END SUB
|
|