新しく発言する  EXIT  インデックスへ
流れ図(フローチャート)を描く

  流れ図(フローチャート)を描く 山中和義 2008/01/09 16:18:14  (修正1回)

流れ図(フローチャート)を描く  返事を書く  ノートメニュー
山中和義 <drdlxujciw> 2008/01/09 16:18:14 ** この記事は1回修正されてます
JIS規格のような矢印を描けませんが、データをつくるだけで簡易に表示できます。


!流れ図(フローチャート)を描く

PICTURE chart(n) !流れ図記号の基本図形
SELECT CASE n
CASE 1 !端子
PLOT LINES: -0.4,0.4; 0.4,0.4
PLOT LINES: -0.4,-0.4; 0.4,-0.4
DRAW arc(90,270) WITH SCALE(0.4)*SHIFT(-0.4,0)
DRAW arc(-90,90) WITH SCALE(0.4)*SHIFT(0.4,0)
CASE 2 !結合子
DRAW arc(0,360) WITH SCALE(0.4)
CASE 3 !処理
PLOT LINES: -0.8,-0.5; 0.8,-0.5; 0.8,0.5; -0.8,0.5; -0.8,-0.5
CASE 4 !定義済み処理
PLOT LINES: -0.8,-0.5; 0.8,-0.5; 0.8,0.5; -0.8,0.5; -0.8,-0.5
PLOT LINES: -0.75,-0.5; -0.75,0.5
PLOT LINES: 0.75,-0.5; 0.75,0.5
CASE 5 !判断
PLOT LINES: -0.8,0; 0,-0.6; 0.8,0; 0,0.6; -0.8,0
CASE 6,16 !繰り返しの開始
PLOT LINES: -0.8,-0.5; 0.8,-0.5; 0.8,0.5; 0.6,0.7; -0.6,0.7; -0.8,0.5; -0.8,-0.5
CASE 7,17 !繰り返しの終了
PLOT LINES: -0.8,0.7; 0.8,0.7; 0.8,-0.3; 0.6,-0.5; -0.6,-0.5; -0.8,-0.3; -0.8,0.7
CASE 8 !手操作入力
PLOT LINES: -0.8,-0.5; 0.8,-0.5; 0.8,0.7; -0.8,0.3; -0.8,-0.5
CASE 9 !表示
PLOT LINES: -0.8,-0.3; 0.8,-0.7; 0.8,0.7; -0.8,0.3; -0.8,-0.3
CASE 10 !入出力
PLOT LINES: -0.9,-0.5; 0.5,-0.5; 0.9,0.5; -0.5,0.5; -0.9,-0.5
CASE 23 !準備
PLOT LINES: -0.9,0; -0.7,-0.5; 0.7,-0.5; 0.9,0; 0.7,0.5; -0.7,0.5; -0.9,0;
CASE ELSE !13
END SELECT
END PICTURE
PICTURE arc(s,e) !円弧を描く
FOR i=s TO e
PLOT LINES: COS(RAD(i)),SIN(RAD(i));
NEXT i
PLOT LINES
END PICTURE

PICTURE ArrowAndComment(d,c$) !「矢印とその注釈」を描く
SET TEXT JUSTIFY "LEFT","HALF"
SELECT CASE d !方向
CASE 0 !右
DRAW arrow WITH SHIFT(0.7,0) !矢印
PLOT TEXT, AT 0.8,0.2: c$ !注釈
CASE 1 !上
DRAW arrow WITH ROTATE(PI/2)*SHIFT(0,0.4)
PLOT TEXT, AT 0.2,0.7: c$
CASE 2 !左
DRAW arrow WITH ROTATE(PI)*SHIFT(-0.7,0)
PLOT TEXT, AT -1.1,0.2: c$
CASE 3 !下
DRAW arrow WITH ROTATE(-PI/2)*SHIFT(0,-0.4)
PLOT TEXT, AT 0.2,-0.7: c$
CASE ELSE
END SELECT
END PICTURE
PICTURE arrow !矢印を描く
PLOT LINES: 0,0; 0.5,0
PLOT AREA: 0.5,0; 0.4,0.05; 0.4,-0.05
END PICTURE

  つづき 山中和義 2008/01/09 16:20:23  (修正1回)
   └流れ図でアルゴリズムを検証する。2008.1.1... 山中和義 2008/01/10 12:53:57  (修正4回)
    ├つづき 山中和義 2008/01/10 12:55:58  (修正4回)
    ├つづき2 山中和義 2008/01/10 13:01:14  (修正4回)
    ├つづき3 山中和義 2008/01/11 21:06:32  (修正2回)
    └つづき4 山中和義 2008/01/13 20:10:24  (修正1回)
     └サンプル(右から左へ受け流す〜♪) 山中和義 2008/01/13 20:18:23  (修正1回)
      └高校数学「数値計算とコンピュータ」 山中和義 2008/01/22 20:37:31  (修正1回)

 インデックスへ  EXIT
新規発言を反映させるにはブラウザの更新ボタンを押してください。