|
|
問題
1/{1+2^(1/3)-4^(1/3)}を有理化せよ。
答え [3+2^(1/3)+2*4^(1/3)}/5
問題
1/{1+2^(1/4)-8^(1/4)}を有理化せよ。
答え {5+2^(1/4)+3*4^(1/4)+2*8^(1/4)}/7
問題
1/{1+64^(1/5)-4^(1/5)}を有理化せよ。
答え {25+9*4^(1/5)+29*16^(1/5)+4*64^(1/5)-5*256^(1/5)}/161
問題
1/{1+2*2^(1/3)+3*2^(2/3)}を有理化せよ。
答え {-11+16*2^(1/3)+2^(2/3)}/89
考察
x=a^(1/3)とおく。
1/(A+Bx+Cx^2)=P+Qx+Rx^2と表されるとすると、x^3=aに注意して、
1=(A+Bx+Cx^2)(P+Qx+Rx^2)=(AP+CaQ+BaR)+(BP+AQ+CaR)x+(CP+BQ+AR)x^2
xの恒等式として、左辺が1なので、
P,Q,Rの連立方程式
AP+CaQ+BaR=1
BP +AQ+CaR=0
CP +BQ +AR=0
を解けばよい。
（終り）
考察
x=a^(1/3)とおく。x^3=aに注意して、
分母は、A+Bx+Cx^2 ← ①
そのx倍は、Ca+Ax+Bx^2 ← ②
そのx^2倍は、Ba+Cax+Ax^2 ← ③
P×①+Q×②+R×③=1となる有理数P,Q,Rを見つける。
P×①+Q×②+R×③
=P(A+Bx+Cx^2)+Q(Ca+Ax+Bx^2)+R(Ba+Cax+Ax^2)
=(AP+CaQ+BaR)+(BP+AQ+CaR)x+(CP+BQ+AR)x^2
なので、
連立方程式
AP+CaQ+BaR=1
BP +AQ+CaR=0
CP +BQ +AR=0
を解けばよい。
（終り）
考察
P,Q,Rの求め方
次の要領で、係数行列をつくる。
・1行目に分母、2行目以降は1列ずつ右へずらす。左下三角行列部分をa倍する。
これは①,②,③の各係数と一致する。
1 x x^2
1倍: A B C
x倍: Ca A B
x^2倍: Ba Ca A
連立方程式(xA=bの形)の右辺は(1,0,…,0)なので、逆行列を求めて、1行目がP,Q,Rとなる。
（終り）
OPTION ARITHMETIC RATIONAL !有理数
!DATA 3,2 !x^3=2
!DATA 1,1,-1 !1+x-x^2
!DATA 4,2 !x^4=2
!DATA 1,1,0,-1 !1+x-x^3
DATA 5,4 !x^5=4
DATA 1,-1,0,1,0 !1+x^3-x
!DATA 5,2 !x^5=2
!DATA 1,2,-1,0,0 !1+2x-x^2
!DATA 3,2 !x^3=2
!DATA 1,2,3 !1+2x+3x^2
READ K,P !x^k=p
DIM M(K,K) !連立方程式 tM=n
FOR J=1 TO K !1行目 Σc[r]x^r
READ M(1,J)
NEXT J
FOR i=2 TO K !2行目以降
LET M(i,1)=M(i-1,K)*P !1列目 x^k=pを適用する
FOR J=2 TO K !2列目以降 右へずらす
LET M(i,J)=M(i-1,J-1)
NEXT J
NEXT i
MAT PRINT M; !debug
DIM T(K,K) !連立方程式を解く
MAT T=INV(M)
MAT PRINT T; !連立方程式の右辺が(1,0,…,0)なので、解P,Q,Rは1行目
END
1/(1+√2-√3)=(2+√2+√6)/4 は2変数多項式になるので手強い。
略解
x=√2、y=√3とおく。
{1,x}×{1,y}={1,x,y,xy}を考える。
DATA 1,1,-1,0 !1倍 1+x-y
DATA 2,1,0,-1 !x倍 2+x-xy
DATA -3,0,1,1 !y倍 -3+y+xy
DATA 0,-3,2,1 !xy倍 -3x+2y+xy
DIM M(4,4)
MAT READ M
!!MAT PRINT M; !debug
DIM T(4,4)
MAT T=INV(M)
MAT PRINT T; !1行目 1,x,y,xyの係数
END
実行結果
1/2 1/4 0 1/4
1/2 1/2 1/2 0
0 3/4 1/2 1/4
3/2 0 1/2 1/2
|
|