新しく発言する EXIT インデックスへ
作れないっす...
　　作れないっす... 有機 2003/08/31 00:36:29 
　　└横軸だったら 白石和夫 2003/08/31 18:20:11 
　　　├あいやー！ありがとうございます。 有機 2003/08/31 19:02:02 
　　　└y=x^2のグラフを対数変換して書きたいのです... 有機 2003/09/04 22:13:07 
　　　　└単に論理が混乱しているだけです。 白石和夫 2003/09/05 12:03:16 
　　　　　└10SETWINDOW-1,12,-1,12 白石和夫 2003/09/05 13:33:04 
　　　　　　└ああ、なるほどー。a*10^nをひとまとめに考... 有機 2003/09/07 18:51:01 
　　　　　　　└両対数グラフのサンプルです。 白石和夫 2003/09/07 22:34:46 

　　作れないっす... 有機 2003/08/31 00:36:29  ツリーへ

作れないっす... 返事を書く
有機 2003/08/31 00:36:29
対数軸描画ルーチン誰か作った人いたらそのソース見せていただけませんかー？ 

　　└横軸だったら 白石和夫 2003/08/31 18:20:11  ツリーへ

Re: 作れないっす... 返事を書く
白石和夫 2003/08/31 18:20:11
横軸だったら
10 SET WINDOW -4,4,-4,4
20 PLOT LINES :-4,0; 4,0
30 SET POINT STYLE 2
40 FOR n=-4 TO 3
50 FOR x=1 TO 10
60 PLOT POINTS: LOG10(x*10^n),0
70 NEXT x
80 NEXT n
90 END
point style 2 は，"＋"です。
 

　　　├あいやー！ありがとうございます。 有機 2003/08/31 19:02:02  ツリーへ

Re: 横軸だったら 返事を書く
有機 2003/08/31 19:02:02
あいやー！ありがとうございます。
これを参考に縦軸も作ってみます。
 

　　　└y=x^2のグラフを対数変換して書きたいのです... 有機 2003/09/04 22:13:07  ツリーへ

Re: 横軸だったら 返事を書く
有機 2003/09/04 22:13:07
y=x^2のグラフを対数変換して書きたいのですがなんと言いますか...
下のように書いたところ、ギザギザのグラフになっちゃいました。
どうしたら正しく変換して対数軸にあったグラフに出来るのでしょうか？ご教授くだされーm(_ _)m


DEF y=x^2
SET WINDOW -1,12,-1,12
PLOT LINES :-1,0; 12,0
PLOT LINES :0,-1; 0,12
SET POINT STYLE 2
FOR n=0 TO 5
FOR a=1 TO 9
PLOT LINES : 2*LOG10(a*10^n),0;2*LOG10(a*10^n),12
NEXT a
NEXT n
FOR m=0 TO 5
FOR b=1 TO 9
PLOT LINES : 0,2*LOG10(b*10^m);12,2*LOG10(b*10^m)
NEXT b
NEXT m

FOR l=0 TO 5
FOR x=1 TO 9 STEP 0.01
PLOT LINES : 2*LOG10(x*10^l),2*LOG10(y*10^l);
NEXT x
NEXT l

END 

　　　　└単に論理が混乱しているだけです。 白石和夫 2003/09/05 12:03:16  ツリーへ

Re: y=x^2のグラフを対数変換して書きたいのです... 返事を書く
白石和夫 2003/09/05 12:03:16
単に論理が混乱しているだけです。
10 SET WINDOW -1,12,-1,12
20 FOR i=-1 TO 11
30 FOR t=1 TO 9 STEP 0.01
40 LET x=t*10^i
50 LET y=x^2
60 PLOT LINES : LOG10(x),LOG10(y);
70 NEXT t
80 NEXT i
90 END
のように，PLOT文では，本来の座標と対数化された座標との変換のみを行い，40行，50行のように，本来の座標値の計算を行う部分を分離して考えやすくするのがコツです。
もちろん、50行と60行を合体して
PLOT LINES : LOG10(x),LOG10(x^2);
としても問題ありません。

 

　　　　　└10SETWINDOW-1,12,-1,12 白石和夫 2003/09/05 13:33:04  ツリーへ

Re: 単に論理が混乱しているだけです。 返事を書く
白石和夫 2003/09/05 13:33:04
10 SET WINDOW -1,12,-1,12
20 FOR t=-1 TO 12 STEP 0.01
30 LET x=10^t
40 LET y=x^2
50 PLOT LINES : LOG10(x),LOG10(y);
60 NEXT t
70 END
のほうがいいかも。
 

　　　　　　└ああ、なるほどー。a*10^nをひとまとめに考... 有機 2003/09/07 18:51:01  ツリーへ

Re: 10SETWINDOW-1,12,-1,12 返事を書く
有機 2003/09/07 18:51:01
ああ、なるほどー。a*10^nをひとまとめに考えるんですね。
言われてみればそうですね(恥)
お手を患わせてしまいすみませんでしたm(_ _)m
ありがとうございました。 

　　　　　　　└両対数グラフのサンプルです。 白石和夫 2003/09/07 22:34:46  ツリーへ

Re: ああ、なるほどー。a*10^nをひとまとめに考... 返事を書く
白石和夫 2003/09/07 22:34:46
両対数グラフのサンプルです。
100 REM 両対数グラフ
110 REM 軌道半径, 公転周期（地球を１とする）
120 DATA 0.39, 0.241 ,水星
130 DATA 0.72, 0.615 ,金星
140 DATA 1 , 1 ,地球
150 DATA 1.52, 1.88 ,火星
160 DATA 5.20, 11.86 ,木星
170 DATA 9.55, 29.46 ,土星
180 DATA 19.2 , 84.01 ,天王星
190 DATA 30.1 , 164.8 ,海王星
200 SET WINDOW -1,3,-1,3
210 SET LINE COLOR 15
220 SET TEXT COLOR 15
230 FOR n=-1 TO 2
240 FOR a=1 TO 9
250 LET x=a*10^n
260 PLOT LINES : LOG10(x),-1; LOG10(x),3
270 NEXT a
280 PLOT TEXT , AT n,-1: STR$(10^n)
290 NEXT n
300 FOR m=-1 TO 3
310 FOR b=1 TO 9
320 LET y=b*10^m
330 PLOT LINES : -1,LOG10(y);3,LOG10(y)
340 NEXT b
350 PLOT TEXT , AT -1, m:STR$(10^m)
360 NEXT m
370 SET TEXT COLOR 1
380 SET TEXT JUSTIFY "left","top"
390 DO
400 READ IF MISSING THEN EXIT DO: x,y,s$
410 LET a=LOG10(x)
420 LET b=LOG10(y)
430 PLOT POINTS: a, b
440 PLOT TEXT ,AT a,b: s$
450 LOOP
460 END

インデックスへ EXIT
新規発言を反映させるにはブラウザの更新ボタンを押してください。