新しく発言する EXIT インデックスへ
走行プログラム
　　走行プログラム ひろ 2004/02/01 11:39:30 
　　├配列を使うよう書き直してみました。 青木太一 2004/02/01 12:18:29 
　　│├ありがとうございます。 ひろ 2004/02/01 12:33:42 
　　││└いや、簡潔かどうかもありますが、 青木太一 2004/02/01 12:52:55 
　　││　└キーフレームその２ 青木太一 2004/02/01 13:43:13 
　　││　　└キーフレームってどういう意味ですか? ひろ 2004/02/01 16:23:12 
　　││　　　└私は素人なので、正確な説明ではないかもし... 青木太一 2004/02/01 20:45:24 
　　││　　　　└すごくよくわかりました。 ひろ 2004/02/01 22:07:01 
　　│└編集可能（配列を使うとうれしいことその２... 青木太一 2004/02/01 21:12:03 
　　├見ました もりの 2004/02/01 12:19:17 
　　│└車ではありませんが ひろ 2004/02/01 17:45:44 
　　│　└実行してみました もりの 2004/02/01 20:00:16 
　　└走行プログラム2 ひろ 2004/02/01 12:35:15 
　　　└ハードル もりの 2004/02/01 16:19:23 
　　　　└ハードルを跳び ひろ 2004/02/01 16:56:46 
　　　　　└そろばんの もりの 2004/02/01 17:06:06 

　　走行プログラム ひろ 2004/02/01 11:39:30  ツリーへ

走行プログラム 返事を書く
ひろ 2004/02/01 11:39:30
走行プログラムを作ってみました。
どんなものか見てください。

RANDOMIZE
DECLARE EXTERNAL PICTURE w1,w2,w3
SET WINDOW 0,10,0,10
DO
DRAW w1
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w3
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w1
LOOP
END

EXTERNAL PICTURE w1
DRAW disk WITH SCALE(1)*SHIFT(5,9)
SET LINE WIDTH 6
PLOT LINES:5,9;5,5
PLOT LINES:5,7.5;5.5,7;6,8
PLOT LINES:5,7.5;4,7;3.8,6.2
PLOT LINES:5,5;6,4.2;6.1,3
PLOT LINES:5,5;4.8,4;3.5,3.5
END PICTURE
EXTERNAL PICTURE w2
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,7.5;5.2,6.6;5.9,6.9
PLOT LINES:5,7.5;4.2,6.9;4.2,6.2
PLOT LINES:5,5;5.6,4;5.3,3
PLOT LINES:5,5;4.7,3.7;3.6,3.7
END PICTURE
EXTERNAL PICTURE w3
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,5;5,3.5;4.2,3.2
PLOT LINES:5,5;5.2,3.8;4.2,3.1
PLOT LINES:5,7.5;4.7,6.6;4.8,6.2
PLOT LINES:5,7.5;5.1,6.5;5.5,6.5
END PICTURE 

　　├配列を使うよう書き直してみました。 青木太一 2004/02/01 12:18:29  ツリーへ

Re: 走行プログラム 返事を書く
青木太一 2004/02/01 12:18:29
配列を使うよう書き直してみました。
こうするとなにがうれしいかというと...

SET WINDOW 0,10,0,10
data 5,9,5,5
data 5,7.5,5.5,7,6,8
data 5,7.5,4,7,3.8,6.2
data 5,5,6,4.2,6.1,3
data 5,5,4.8,4,3.5,3.5

data 5,9,5,5
data 5,7.5,5.2,6.6,5.9,6.9
data 5,7.5,4.2,6.9,4.2,6.2
data 5,5,5.6,4,5.3,3
data 5,5,4.7,3.7,3.6,3.7

data 5,9,5,5
data 5,5,5,3.5,4.2,3.2
data 5,5,5.2,3.8,4.2,3.1
data 5,7.5,4.7,6.6,4.8,6.2
data 5,7.5,5.1,6.5,5.5,6.5

LET n=14
LET frame=3
dim x(1 to 15,1 to frame),y(1 to 15,1 to frame)
for j=1 to frame
for i=1 to n
read x(i,j),y(i,j)
next i
next j

data 2,5,8,11,14
LET cut_n=5
dim cut(1 to cut_n)
for i=1 to cut_n
read cut(i)
next i

do
for j=1 to frame

WAIT DELAY 0.1
SET LINE WIDTH 6
DRAW disk WITH SCALE(1)*SHIFT(5,9)
for i=1 to n
plot lines: x(i,j),y(i,j);
for k=1 to cut_n
if i=cut(k) then plot lines
next k
next i
set draw mode explicit
set draw mode hidden
clear

next j
loop
end 

　　│├ありがとうございます。 ひろ 2004/02/01 12:33:42  ツリーへ

Re: 配列を使うよう書き直してみました。 返事を書く
ひろ 2004/02/01 12:33:42
ありがとうございます。
ずいぶん簡単になりましたね。
私もここまで簡潔にかけるように努力したいです。
 

　　││└いや、簡潔かどうかもありますが、 青木太一 2004/02/01 12:52:55  ツリーへ

Re: ありがとうございます。 返事を書く
青木太一 2004/02/01 12:52:55
いや、簡潔かどうかもありますが、
キーフレームをつかったなめらかなアニメーションに簡単に変更できます。
「そんなの知ってるよ」ということだったら失礼。

(簡単と言っておきながら、キーフレーム法がつかいやすいように、ひろさんのdataの順番変えたり増やしたりしていますが...)

SET WINDOW 0,10,0,10
data 5,9,5,5
data 5,7.5,5.5,7,6,8
data 5,7.5,4,7,3.8,6.2
data 5,5,6,4.2,6.1,3
data 5,5,4.8,4,3.5,3.5

data 5,9,5,5
data 5,7.5,5.2,6.6,5.9,6.9
data 5,7.5,4.2,6.9,4.2,6.2
data 5,5,5.6,4,5.3,3
data 5,5,4.7,3.7,3.6,3.7

data 5,9,5,5
data 5,7.5,5.1,6.5,5.5,6.5
data 5,7.5,4.7,6.6,4.8,6.2
data 5,5,5.2,3.8,4.2,3.1
data 5,5,5,3.5,4.2,3.2

data 5,9,5,5
data 5,7.5,4.7,6.6,4.8,6.2
data 5,7.5,5.1,6.5,5.5,6.5
data 5,5,5,3.5,4.2,3.2
data 5,5,5.2,3.8,4.2,3.1

data 5,9,5,5
data 5,7.5,4.2,6.9,4.2,6.2
data 5,7.5,5.2,6.6,5.9,6.9
data 5,5,4.7,3.7,3.6,3.7
data 5,5,5.6,4,5.3,3

data 5,9,5,5
data 5,7.5,4,7,3.8,6.2
data 5,7.5,5.5,7,6,8
data 5,5,4.8,4,3.5,3.5
data 5,5,6,4.2,6.1,3
LET n=14
LET frame=6
dim x(1 to 15,1 to frame),y(1 to 15,1 to frame)
for j=1 to frame
for i=1 to n
read x(i,j),y(i,j)
next i
next j

data 2,5,8,11,14
LET cut_n=5
dim cut(1 to cut_n)
for i=1 to cut_n
read cut(i)
next i

dim xx(1 to n),yy(1 to n)
SET LINE WIDTH 6
LET speed=0.05
do
for j=1 to frame-1
for a=0 to 1 step speed

LET run_x=run_x+speed*0.2
if run_x>5 then LET run_x=-5

for i=1 to n
LET xx(i)=x(i,j)*(1-a)+x(i,j+1)*a
LET yy(i)=y(i,j)*(1-a)+y(i,j+1)*a
next i
draw body with shift(run_x,o)
set draw mode explicit
set draw mode hidden
clear

next a
next j
loop

picture body
DRAW disk WITH SCALE(1)*SHIFT(5,9)
for i=1 to n
plot lines: xx(i),yy(i);
for k=1 to cut_n
if i=cut(k) then plot lines
next k
next i
end picture

END
 

　　││　└キーフレームその２ 青木太一 2004/02/01 13:43:13  ツリーへ

Re: いや、簡潔かどうかもありますが、 返事を書く
青木太一 2004/02/01 13:43:13
キーフレームその２

こっちの方がもりのさんのデータに忠実です。
(基本的にフレームを3枚しか使わないところが)

パラメータもいろいろ変えましたが...

LET window_size=20
SET WINDOW 0,window_size,0,window_size
!一枚目
data 5,9,5,5
data 5,7.5,5.5,7,6,8
data 5,7.5,4,7,3.8,6.2
data 5,5,6,4.2,6.1,3
data 5,5,4.8,4,3.5,3.5
!二枚目
data 5,9,5,5
data 5,7.5,5.2,6.6,5.9,6.9
data 5,7.5,4.2,6.9,4.2,6.2
data 5,5,5.6,4,5.3,3
data 5,5,4.7,3.7,3.6,3.7
!三枚目
data 5,9,5,5
data 5,7.5,4.7,6.6,4.8,6.2
data 5,7.5,5.1,6.5,5.5,6.5
data 5,5,5,3.5,4.2,3.2
data 5,5,5.2,3.8,4.2,3.1
!四枚目
data 5,9,5,5
data 5,7.5,4,7,3.8,6.2
data 5,7.5,5.5,7,6,8
data 5,5,4.8,4,3.5,3.5
data 5,5,6,4.2,6.1,3

LET n=14!点の数
LET frame=4!フレームの枚数
dim x(1 to 15,1 to frame),y(1 to 15,1 to frame)
!フレームデータの読み込み
for j=1 to frame
for i=1 to n
read x(i,j),y(i,j)
next i
next j

!どこで線を切るか
data 2,5,8,11,14
LET cut_n=5
dim cut(1 to cut_n)
for i=1 to cut_n
read cut(i)
next i

dim xx(1 to n),yy(1 to n)
SET LINE WIDTH 2
LET speed=0.05
!ここからメインループ
do
for j=1 to frame-1
for a=0 to 1 step speed

LET run_x=run_x+speed*0.765!x方向の移動
if run_x>window_size-4 then LET run_x=-6

!次のフレームと今のフレームを補間
for i=1 to n
LET xx(i)=x(i,j)*(1-a)+x(i,j+1)*a
LET yy(i)=y(i,j)*(1-a)+y(i,j+1)*a
next i

!描いて消す
draw body with shift(run_x,o)
set draw mode explicit
set draw mode hidden
clear

next a
next j
loop
!メインループここまで

!体を描く
picture body
DRAW disk WITH SCALE(1)*SHIFT(5,9)
for i=1 to n
plot lines: xx(i),yy(i);
for k=1 to cut_n
if i=cut(k) then plot lines
next k
next i
end picture

END
 

　　││　　└キーフレームってどういう意味ですか? ひろ 2004/02/01 16:23:12  ツリーへ

Re: キーフレームその２ 返事を書く
ひろ 2004/02/01 16:23:12
キーフレームってどういう意味ですか?
どうやったらあんななめらかな動きができるんですか?
私は知りません。
青木さんのプログラムを見てもいまいちわかりません。
教えてください。
お願いします。 

　　││　　　└私は素人なので、正確な説明ではないかもし... 青木太一 2004/02/01 20:45:24  ツリーへ

Re: キーフレームってどういう意味ですか? 返事を書く
青木太一 2004/02/01 20:45:24
私は素人なので、正確な説明ではないかもしれないという前提でお願いします。

＜＜アニメーションの原理＞＞
アニメーションは原理的にははパラパラ漫画です。
たくさんの絵を次々と見せることで絵が動いているように見えます。
一つの動作を表す画像の枚数が多いほどスムーズな動作に見えます。
しかしたくさんの画像を用意するのは大変です。

＜＜キーフレームアニメーション＞＞
だったら、人間が大まかに動きを表す絵を描き、(ひろさんのように３枚描き)
間の絵はコンピュータに作ってもらえばいいのです。

＜＜例１＞＞
以下、２カ所の点を決め、間はコンピュータに作ってもらっている例です。
set window 0,1,-1,1
dim x(2)
LET x(1)=0.2
LET x(2)=0.8
for a=0 to 1 step 0.005
plot points:x(1)*(1-a)+x(2)*a,0
set draw mode explicit
set draw mode hidden
clear
next a
END
画像が２つだけのときはモーフィングという言い方もします。

＜＜例２＞＞
コマが２つより多いとプログラムは若干ややこしいですが、基本的には同じです。
あるコマと、その次のコマの間で例１と同じことをやるのです。
randomize
set window 0,1,0,1
LET frame=4 !コマ数
dim x(1 to frame),y(1 to frame)
do
!点の位置を決める
for i=1 to frame
LET x(i)=rnd
LET y(i)=rnd
next i
for j=1 to frame-1
for a=0 to 1 step 0.005

!説明用に全部のフレームを
for i=1 to frame
plot text,at x(i),y(i):str$(i)
plot points:x(i),y(i)
next i

LET xx=x(j)*(1-a)+x(j+1)*a!ここで二つのコマを混合している
LET yy=y(j)*(1-a)+y(j+1)*a
plot points:xx,yy

plot text,at 0,0:"混合率　今のフレーム＝"&using$("%.###",1-a)&" 次のフレーム＝"&using$("%.###",a)
set draw mode explicit
set draw mode hidden
clear
next a
next j
pause
loop
END

ところで、知らない単語があったらGoogleやYahooなどの検索エンジンで探すといいですよ。
「キーフレーム」の他にも「補間」、「モーフィング」といったキーワードで調べるといいかもしれません。
今回は、簡単に説明をしているページが見つからなかったので一応書きました。
(結局わかりにくい説明になっているかもしれませんが)

英語でいいならここのデモがわかりやすいかもしれません(要Flash)
http://animation.about.com/library/weekly/blglossarykeyframe.htm

以下はモーフィング、キーフレームアニメーションを活用したわかりやすいソフトです
http://www.sharp.co.jp/sc/excite/evademo/evahome.htm
http://www.cim.pe.u-tokyo.ac.jp/~mitani/munimuni/index.html

言葉としては、もともとはCGではない実際のアニメーション制作現場で
まず「おおまかな動きのコマ(キーフレーム(原画))」を描いてから
「間を埋めるコマ(動画)」を描いていることからくるようです。
 

　　││　　　　└すごくよくわかりました。 ひろ 2004/02/01 22:07:01  ツリーへ

Re: 私は素人なので、正確な説明ではないかもし... 返事を書く
ひろ 2004/02/01 22:07:01
すごくよくわかりました。
青木さんは教えることに向いているのではないでしょうか。
これからはキーフレームを活用させていただきます。 

　　│└編集可能（配列を使うとうれしいことその２... 青木太一 2004/02/01 21:12:03  ツリーへ

Re: 配列を使うよう書き直してみました。 返事を書く
青木太一 2004/02/01 21:12:03
編集可能（配列を使うとうれしいことその２）

動画とは関係ありませんが...
すでに思いついていたら失礼。

!マウスで棒人間を編集
!マウス左ボタンで編集
!マウス右ボタンでデータ書き出し
SET WINDOW 0,10,0,10
!データ
data 5,9,5,5
data 5,7.5,5.5,7,6,8
data 5,7.5,4,7,3.8,6.2
data 5,5,6,4.2,6.1,3
data 5,5,4.8,4,3.5,3.5
!データ読み込み
LET n=14
dim x(1 to 15),y(1 to 15)
for i=1 to n
read x(i),y(i)
next i
!線を切るタイミングデータ
data 2,5,8,11,14
LET cut_n=5
dim cut(1 to cut_n)
for i=1 to cut_n
read cut(i)
next i

!メインループここから
do
mouse poll mx,my,ml,mr

!マウスに一番近い距離の点を選ぶ
LET near_d=MAXNUM
for i=1 to n
LET distance=sqr((mx-x(i))^2+(my-y(i))^2)!マウスと点の距離
if distance<near_d then
LET near_d=distance
LET near_i=i
end if
next i

!マウス左ボタンが押されていたら、一番近い点をマウスの場所へ
if ml=1 then
LET x(near_i)=mx
LET y(near_i)=my
end if

draw body!棒人間を描く
set point color 4!マウスに一番近い点を違う色で描く
plot points:x(near_i),y(near_i)
set point color 1

set draw mode explicit
if mr=1 then exit do!マウス右ボタンが押されたらループ抜ける
set draw mode hidden
clear
loop
!メインループここまで

!データ書き出し
print "data";
for i=1 to n
print x(i);",";y(i);
for k=1 to cut_n-1
if i=cut(k) then
print
print "data";
exit for
end if
next k
if k=cut_n and i<n then print ",";
next i

!棒人間
picture body
for i=1 to n
plot points:x(i),y(i)
plot lines: x(i),y(i);
for k=1 to cut_n
if i=cut(k) then plot lines
next k
next i
end picture

end 

　　├見ました もりの 2004/02/01 12:19:17  ツリーへ

Re: 走行プログラム 返事を書く
もりの 2004/02/01 12:19:17
見ました
前に授業で何種類の車が
走っている場面をこどもに
見せて
消防車は何台通りましたか
乗用車は何台通りましたか
バイクは何台通りましたか
と質問をし
その結果をグラフに書かせたことが
あります
何台通りましたか？
と質問し

正解はといった

そのあとクリック一発で種類ごとに
棒グラフにするなんて
できないよね！？

 

　　│└車ではありませんが ひろ 2004/02/01 17:45:44  ツリーへ

Re: 見ました 返事を書く
ひろ 2004/02/01 17:45:44
車ではありませんが
円でならできました。

RANDOMIZE
SET WINDOW 0,10,0,10
DIM A(3)
FOR H=1 TO 10
LET C=INT(RND*3+1)
LET y=INT(RND*10+1)
LET A(C)=A(C)+1
FOR x=10 TO 0 STEP -0.1
SET COLOR C
DRAW disk WITH SCALE(0.5)*SHIFT(x,y)
set draw mode explicit
set draw mode hidden
clear
NEXT x
NEXT H
set draw mode explicit
INPUT PROMPT "黒青緑":b,c,d
IF A(1)=b AND A(2)=c AND A(3)=d THEN GOTO 10
GOTO 20
10 SET TEXT FONT "ＭＳ 明朝",100
SET COLOR 4
PLOT TEXT ,AT 2.5,4 : "正解"
GOTO 30
20 SET TEXT FONT "ＭＳ 明朝",100
SET COLOR 4
PLOT TEXT ,AT 2.5,4 : "残念"
30 GET POINT:x,y
clear
SET COLOR 1
SET TEXT FONT "ＭＳ 明朝",20
PLOT LINES:1,10;1,1;10,1
PLOT TEXT ,AT 0.5,1 :"0"
PLOT TEXT ,AT 0.5,2 :"1"
PLOT TEXT ,AT 0.5,3 :"2"
PLOT TEXT ,AT 0.5,4 : "3"
PLOT TEXT ,AT 0.5,5 : "4"
PLOT TEXT ,AT 0.5,6 : "5"
PLOT TEXT ,AT 0.5,7 : "6"
PLOT TEXT ,AT 0.5,8 :"7"
PLOT TEXT ,AT 0.5,9 : "8"
PLOT TEXT ,AT 2.5,0 : "黒"
PLOT TEXT ,AT 5.8,0 : "青"
PLOT TEXT ,AT 8.5,0 : "緑"
SET COLOR 1
PLOT AREA:2,1;2,A(1)+1;4,A(1)+1;4,1
SET COLOR 2
PLOT AREA:5,1;5,A(2)+1;7,A(2)+1;7,1
SET COLOR 3
PLOT AREA:8,1;8,A(3)+1;10,A(3)+1;10,1
END 

　　│　└実行してみました もりの 2004/02/01 20:00:16  ツリーへ

Re: 車ではありませんが 返事を書く
もりの 2004/02/01 20:00:16
実行してみました
いいと思います
あと色の種類を何種類に
しますか？
と

何秒間表示しますか？

という

入力枠があり
そのたびに種類の数や
表示時間がかえられると

いろいろな棒グラフを
つくる学習ができます。
改良できますかね。

 

　　└走行プログラム2 ひろ 2004/02/01 12:35:15  ツリーへ

Re: 走行プログラム 返事を書く
ひろ 2004/02/01 12:35:15
走行プログラム2
今度はより走っているとわかるようになりました。

RANDOMIZE
DECLARE EXTERNAL PICTURE w1,w2,w3
SET WINDOW 0,50,0,50
FOR b=0 TO 50
DRAW w1 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w3 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w1 WITH SHIFT(b,5)
set draw mode explicit
set draw mode hidden
clear

NEXT b
FOR b=0 TO 50
DRAW w1 WITH SHIFT(b,10)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2 WITH SHIFT(b,10)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w3 WITH SHIFT(b,10)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2 WITH SHIFT(b,10)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w1 WITH SHIFT(b,10)
set draw mode explicit
set draw mode hidden
clear

NEXT b
FOR b=0 TO 50
DRAW w1 WITH SHIFT(b,15)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2 WITH SHIFT(b,15)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w3 WITH SHIFT(b,15)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w2 WITH SHIFT(b,15)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
DRAW w1 WITH SHIFT(b,15)
set draw mode explicit
set draw mode hidden
clear

NEXT b

END

EXTERNAL PICTURE w1
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,7.5;5.5,7;6,8
PLOT LINES:5,7.5;4,7;3.8,6.2
PLOT LINES:5,5;6,4.2;6.1,3
PLOT LINES:5,5;4.8,4;3.5,3.5
END PICTURE
EXTERNAL PICTURE w2
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,7.5;5.2,6.6;5.9,6.9
PLOT LINES:5,7.5;4.2,6.9;4.2,6.2
PLOT LINES:5,5;5.6,4;5.3,3
PLOT LINES:5,5;4.7,3.7;3.6,3.7
END PICTURE
EXTERNAL PICTURE w3
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,5;5,3.5;4.2,3.2
PLOT LINES:5,5;5.2,3.8;4.2,3.1
PLOT LINES:5,7.5;4.7,6.6;4.8,6.2
PLOT LINES:5,7.5;5.1,6.5;5.5,6.5
END PICTURE 

　　　└ハードル もりの 2004/02/01 16:19:23  ツリーへ

Re: 走行プログラム2 返事を書く
もりの 2004/02/01 16:19:23
ハードル

この前頼まれて体育の授業をしました
たまたまハードルだったんだけど

このプロでハードルを
飛ぶときの注意とか
クリックでとめながらできるといいね
もっと足をながくしたり人にいろを
ぬれたり
人間らしくなると
いいね
毎回うるさくてごめんなさい
 

　　　　└ハードルを跳び ひろ 2004/02/01 16:56:46  ツリーへ

Re: ハードル 返事を書く
ひろ 2004/02/01 16:56:46
ハードルを跳び
クリックをすれば止まる
できましたよ

DECLARE EXTERNAL PICTURE w1,w2,w3
SET WINDOW 0,50,0,50
FOR a=0 TO 20
MOUSE POLL x,y,l,r
IF l=1 THEN PAUSE
SET LINE COLOR 4
PLOT LINES:30,8;30,11
SET COLOR 1
LET b=b+0.2
DRAW w1 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
MOUSE POLL x,y,l,r
IF l=1 THEN PAUSE
PLOT LINES:30,8;30,11
LET b=b+0.2
DRAW w2 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
MOUSE POLL x,y,l,r
IF l=1 THEN PAUSE
PLOT LINES:30,8;30,11
LET b=b+0.2
DRAW w3 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
MOUSE POLL x,y,l,r
IF l=1 THEN PAUSE
PLOT LINES:30,8;30,11
LET b=b+0.2
DRAW w2 WITH SHIFT(b,5)
WAIT DELAY 0.1
set draw mode explicit
set draw mode hidden
clear
MOUSE POLL x,y,l,r
IF l=1 THEN PAUSE
PLOT LINES:30,8;30,11
LET b=b+0.2
DRAW w1 WITH SHIFT(b,5)
set draw mode explicit
set draw mode hidden
clear
NEXT a
FOR t=0 TO 2 STEP 0.01
MOUSE POLL x,y,l,r
IF l=1 THEN PAUSE
PLOT LINES:30,8;30,11
DRAW w1 WITH SHIFT(21+5*t,5+10*t-4.9*t*t)
set draw mode explicit
set draw mode hidden
clear
NEXT t
END

EXTERNAL PICTURE w1
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,7.5;5.5,7;6,8
PLOT LINES:5,7.5;4,7;3.8,6.2
PLOT LINES:5,5;6,4.2;6.1,3
PLOT LINES:5,5;4.8,4;3.5,3.5
END PICTURE
EXTERNAL PICTURE w2
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,7.5;5.2,6.6;5.9,6.9
PLOT LINES:5,7.5;4.2,6.9;4.2,6.2
PLOT LINES:5,5;5.6,4;5.3,3
PLOT LINES:5,5;4.7,3.7;3.6,3.7
END PICTURE
EXTERNAL PICTURE w3
DRAW disk WITH SCALE(1)*SHIFT(5,9)
PLOT LINES:5,9;5,5
PLOT LINES:5,5;5,3.5;4.2,3.2
PLOT LINES:5,5;5.2,3.8;4.2,3.1
PLOT LINES:5,7.5;4.7,6.6;4.8,6.2
PLOT LINES:5,7.5;5.1,6.5;5.5,6.5
END PICTURE 

　　　　　└そろばんの もりの 2004/02/01 17:06:06  ツリーへ

Re: ハードルを跳び 返事を書く
もりの 2004/02/01 17:06:06
そろばんの
クリツクの
ヤジルシと
ことば
枠
できますか？

ハードルはもう少し工夫すると
なおよくなりますね。

インデックスへ EXIT
新規発言を反映させるにはブラウザの更新ボタンを押してください。