途中から、数字だけが、大きくなってしまい...

!途中から、数字だけが、大きくなってしまいます、原因が分かりません。

!--------------------------------------------------------
!マトリクスで写像。

!“ 絵 ”の各ドットは、４次の行ベクトル、なので、4x4 行列(matrix)で加工できる。

!原画_行ベクトル　　　　出力画_行ベクトル
!　　（X,Y,Z,1)|1 0 0 0|　→（X,Y,Z,1）　Z 座標は無効なのだが、3D.遠近 → 縮小拡大
!　　　　　　　|0 1 0 0|　　　　　　　　　　　　　　　　　などの、途中の計算で有用。
!　　　　　　　|0 0 1 0|　　　　4 列目の1 ＝描画倍率の逆数。
!　　　　　　　|0 0 0 1|　　　　これが０だと、∞倍となり、何も表示されない。標準１。
!　　　　　　　　　　　　　　　　　　　　　　　　　　　　　1 の他は、3D.遠近で使用。

DIM A(4,4), B(4,4), C(4,4)

LET φ=(1+SQR(5))/2 !黄金比

!scale(1/φ)のマトリクス A
MAT A=IDN !単位行列のセット
LET A(1,1)=1/φ
LET A(2,2)=1/φ
!-----
! 1/φ,0 　, 0, 0|
! 0 　,1/φ, 0, 0|
! 0 　,0 　, 1, 0|
! 0 　,0 　, 0, 1|

!shift(0, 1/φ)のマトリクス B
MAT B=IDN !単位行列のセット
LET B(4,2)=1/φ
!-----
! 1 ,0 　, 0, 0|
! 0 ,1 　, 0, 0|
! 0 ,0 　, 1, 0|
! 0 ,1/φ, 0, 1|

!rotate(-90)のマトリクス C
!READ される「行」と「列」の配置は、DATA 文の並びの通りになる。
MAT READ C
DATA 0,-1,0,0 !　　| cos(-90), sin(-90)|
DATA 1, 0,0,0 !　　|-sin(-90), cos(-90)|
DATA 0, 0,1,0
DATA 0, 0,0,1

!アニメーションにする。

OPTION ANGLE DEGREES
SET WINDOW -1.1,0.7, -0.4,1.4

SET COLOR MIX(15) 0,0,0 !黒色:GRID
DRAW GRID

PLOT LINES: 1/φ, 0.9; 1/φ, 1.1
PLOT TEXT,AT 0.31, 1.12: STR$(φ-1) !目盛り
SET TEXT FONT "",100

PICTURE arc(m)
!-----　原画“ 絵 ”１枚
SET DRAW mode hidden !裏ページに書く
FOR t=90 TO 180
PLOT LINES: COS(t),SIN(t); !円弧
NEXT t
PLOT LINES: -1,1; 0,1; 0,0; -1,0 !正方形
paint -0.8,0.8
PLOT TEXT,AT -0.6,0.2:STR$(m) !数字
SET DRAW mode explicit !裏ページの表示

WAIT DELAY 0.3

!-----　マトリクスで写像。
IF 0<m THEN DRAW arc(m-1) WITH C*B*A !再帰draw
END PICTURE

DRAW arc(15) !段数

END

途中から、数字だけが、大きくなってしまいます、原因が分かりません。	返事を書くノートメニュー
SECOND <cszcthjjdj> 2007/05/18 01:30:59
!途中から、数字だけが、大きくなってしまいます、原因が分かりません。 !-------------------------------------------------------- !マトリクスで写像。 !“ 絵 ”の各ドットは、４次の行ベクトル、なので、4x4 行列(matrix)で加工できる。 !原画_行ベクトル　　　　出力画_行ベクトル !　　（X,Y,Z,1)\|1 0 0 0\|　→（X,Y,Z,1）　Z 座標は無効なのだが、3D.遠近 → 縮小拡大 !　　　　　　　\|0 1 0 0\|　　　　　　　　　　　　　　　　　などの、途中の計算で有用。 !　　　　　　　\|0 0 1 0\|　　　　4 列目の1 ＝描画倍率の逆数。 !　　　　　　　\|0 0 0 1\|　　　　これが０だと、∞倍となり、何も表示されない。標準１。 !　　　　　　　　　　　　　　　　　　　　　　　　　　　　　1 の他は、3D.遠近で使用。 DIM A(4,4), B(4,4), C(4,4) LET φ=(1+SQR(5))/2 !黄金比 !scale(1/φ)のマトリクス A MAT A=IDN !単位行列のセット LET A(1,1)=1/φ LET A(2,2)=1/φ !----- ! 1/φ,0 　, 0, 0\| ! 0 　,1/φ, 0, 0\| ! 0 　,0 　, 1, 0\| ! 0 　,0 　, 0, 1\| !shift(0, 1/φ)のマトリクス B MAT B=IDN !単位行列のセット LET B(4,2)=1/φ !----- ! 1 ,0 　, 0, 0\| ! 0 ,1 　, 0, 0\| ! 0 ,0 　, 1, 0\| ! 0 ,1/φ, 0, 1\| !rotate(-90)のマトリクス C !READ される「行」と「列」の配置は、DATA 文の並びの通りになる。 MAT READ C DATA 0,-1,0,0 !　　\| cos(-90), sin(-90)\| DATA 1, 0,0,0 !　　\|-sin(-90), cos(-90)\| DATA 0, 0,1,0 DATA 0, 0,0,1 !アニメーションにする。 OPTION ANGLE DEGREES SET WINDOW -1.1,0.7, -0.4,1.4 SET COLOR MIX(15) 0,0,0 !黒色:GRID DRAW GRID PLOT LINES: 1/φ, 0.9; 1/φ, 1.1 PLOT TEXT,AT 0.31, 1.12: STR$(φ-1) !目盛り SET TEXT FONT "",100 PICTURE arc(m) !-----　原画“ 絵 ”１枚 SET DRAW mode hidden !裏ページに書く FOR t=90 TO 180 PLOT LINES: COS(t),SIN(t); !円弧 NEXT t PLOT LINES: -1,1; 0,1; 0,0; -1,0 !正方形 paint -0.8,0.8 PLOT TEXT,AT -0.6,0.2:STR$(m) !数字 SET DRAW mode explicit !裏ページの表示 WAIT DELAY 0.3 !-----　マトリクスで写像。 IF 0<m THEN DRAW arc(m-1) WITH CBA !再帰draw END PICTURE DRAW arc(15) !段数 END

Re: 途中から、数字だけが、大きくなってしまいます、原因が分かりません。	返事を書くノートメニュー
白石　和夫 <fbdfvqwhki> 2007/05/18 14:48:24 ** この記事は2回修正されてます
内部で整数値でフォントの高さを指定していますが，その値が0であると既定値を指定したものとみなされるみたいです。次バージョンで修正します。

Re: 内部で整数値でフォントの高さを指定してい...	返事を書くノートメニュー
白石　和夫 <fbdfvqwhki> 2007/05/28 18:16:14
ver. 5.9.9で修正しました。